Интересная задачка по getFirst - getNext

[Wamr]

Задача - просуммировать физ. наличие по выделенным строкам в форме "В наличии" (InventOnHandItem).

Если считать по BP, то результат будет неправильный (значение из текущей записи)

PHP код:

void clicked()
{
    InventSum   inventSumLocal;
    InventQty   qty;
    ;

    super();

    for(inventSumLocal = InventSum_ds.getFirst(1) ? InventSum_ds.getFirst(1) : InventSum_ds.cursor();
        InventSumLocal;
        InventSumLocal = InventSum_ds.getNext())
    {
        qty += InventSumLocal.PhysicalInvent;
    }

    info(strFmt("PhysicalInvent = %1", qty));
} 


Какие будут предложения?

[George Nordic]

Приветствую, Wamr!

Предложения вот такие:

PHP код:

      for(inventSumLocal = InventSum_ds.getFirst(true) ? InventSum_ds.getFirst(true) : InventSum_ds.cursor();
         inventSumLocal.PhysicalInvent;
         inventSumLocal = InventSum_ds.getNext())
    {
        qty += InventSumLocal.PhysicalInvent;
    }
    info(strFmt("PhysicalInvent = %1", qty)); 


Обрати внимание, что inventSumLocal.RecId == 0 (?)

C Уважением,
Георгий.

[Maxim Gorbunov]

Прикольно.

В общем, такой эффект от того, что в при приведении типов Common -> boolean используется (InventSumLocal.RecId != 0) В форме "В наличии" запрос так переколбасивается, что RecId просто не выбирается из InventSum.

Бороться с этим можно по-разному. Например, так: добавьте в InventSum_ds.init() последней строкой (после вызова initQueryInventSum()) следующий код:

PHP код:

inventSum_ds.query().dataSourceTable(this.table()).addSelectionField(fieldNum(InventSum, RecId), SelectionField::Min); 


Тогда для всех строчек InventSum_ds будет выбираться ненулевой RecId. А больше ничего и не надо.

[Maxim Gorbunov]

Не, Георгий, так не пойдет. А если среди суммируемых строк будет и строка с нулевым PhysicalInvent?

[Wamr]

Я знал, что вам понравится

Максим, как всегда, прав.

Георгий, наверное имел ввиду, сделать inventSumLocal.ItemId ?
но это повличет интересный эффект - если маркировать строчки снизу вверх, то все посчитается правильно, а сверху вниз нет

[Maxim Gorbunov]

А ItemId, кстати, тоже не обязательно будет выбираться. С помощью кнопки Отображение аналитики в форме В наличии код номенклатуры можно отключить

[George Nordic]

Цитата:

Изначально опубликовано Wamr
Георгий, наверное имел ввиду, сделать inventSumLocal.ItemId?

Ну, я искал альтернативу RecId

Но эффект все равно забавный "Улыбнуло. Афтар пеши исчто!"

С Уважением,
Георгий.

[Wamr]

Максим, аха.. отключить-то можно, и даже из грида пропадет... но в запросе-то останется (только что проверил)

[trud]

Предложу более универсальное решение, которое будет работать независимо от того, какие поля заполнены в InventSum

PHP код:

    InventSum   inventSumLocal;
    Common      inventSumCommon;
    InventQty   qty;
    ;

    super();

    for(inventSumCommon = InventSum_ds.getFirst() ? InventSum_ds.getFirst() : InventSum_ds.cursor();
        inventSumCommon.TableId != tablenum(Common);
        inventSumCommon = InventSum_ds.getNext())
    {
        InventSumLocal = inventSumCommon;
        qty += InventSumLocal.PhysicalInvent;
    }
    info(strFmt("PhysicalInvent = %1", qty)); 


[Maxim Gorbunov]

Цитата:

Изначально опубликовано Wamr
Максим, аха.. отключить-то можно, и даже из грида пропадет... но в запросе-то останется (только что проверил)

OK. Согласен.

[Maxim Gorbunov]

Цитата:

Изначально опубликовано trud
Предложу более универсальное решение, которое будет работать независимо от того, какие поля заполнены в InventSum

Тоже интересный вариант. Только true Вы забыли передать в getFirst().

[Wamr]

Интересный, только имеет тотже трабл, что и вариант Георгия.

Почему-то все забывают про тройной оператор "? : ", в котором делается сравнение с курсором RecId =0. В результате вместо первой записи из выделенных всегда берется текущая запись.

PHP код:

    InventSum   inventSumLocal;
    Common      inventSumCommon;
    InventQty   qty;
    ;

    super();

    for(inventSumCommon = InventSum_ds.getFirst(1).TableId != tablenum(Common) ?
        InventSum_ds.getFirst(1) : InventSum_ds.cursor();
        inventSumCommon.TableId != tablenum(Common);
        inventSumCommon = InventSum_ds.getNext())
    {
        InventSumLocal = inventSumCommon;
        qty += InventSumLocal.PhysicalInvent;
    }
    info(strFmt("PhysicalInvent = %1", qty)); 


[Maxim Gorbunov]

Я, кстати, тоже заметил, когда тестировал этот вариант, что один раз сглюкнуло, но почему - разбираться не стал. Спасибо, Wamr.