PhysicalInvent

[DreamCreator]

Доброе утро!

Корректно ли таким образом считать количество в наличии по склау:

PHP код:

static void QtyOnHand(Args _args)
{
    InventSum   inventSum;
    InventDim   inventDim;
    ;

    inventDim.clear();
    inventDim.InventLocationId = 'MyWarehouse';
    inventDim = InventDim::findOrCreate(inventDim);

    while select inventSum 
        join inventDim
            where   inventSum.InventDimId == inventDim.inventDimId
            {
                print strfmt("%1    %2",inventSum.ItemId,inventSum.physicalInvent());
            }
   pause;
} 


?

[George Nordic]

Слушай, что-то мудрено

Посмотри класс inventOnHand - по-моему это то, что тебе надо!

С Уважением,
Георгий.

DreamCreator

Так совсем неправильно. Если с классом разбираться влом, запрос надо писать типа такого:

PHP код:

    InventSum           inventSum;
    InventDim           inventDim;
    InventLocationId    invId   = "111";
    ItemId                       itemId  = "xxx";
    ;

    select 
        sum(physicalInvent) from
        inventSum
            where
                inventSum.ItemId            == itemId
        join
        inventDim
            group by inventLocationId
            where
                inventSum.InventDimId       ==  inventDim.inventDimId
             && inventDim.InventLocationId  ==  invId;

    info(strfmt("%1", inventSum.PhysicalInvent)); 


Еще есть макросы для линковки InventDim.

[DreamCreator]

Спасибо!
Я написал так:

PHP код:

static void QtyOnHand(Args _args)
{
    InventDim       inventDim;
    InventDimParm   inventDimParm;
    ItemId          itemId;
    ;

    itemId = '000000001';

    inventDim.InventLocationId = 'MyWarehouse';

    inventDimParm.InventLocationIdFlag = NoYes::Yes;

    print InventOnHand::newParameters(itemId,inventDim,inventDimParm,false).physicalInvent();

    pause;
} 


[Recoilme]

Цитата:

Изначально опубликовано Chris2005
DreamCreator

Так совсем неправильно. Если с классом разбираться влом, запрос надо писать типа такого:

PHP код:

    InventSum           inventSum;
    InventDim           inventDim;
    InventLocationId    invId   = "111";
    ItemId                       itemId  = "xxx";
    ;

    select 
        sum(physicalInvent) from
        inventSum
            where
                inventSum.ItemId            == itemId
        join
        inventDim
            group by inventLocationId
            where
                inventSum.InventDimId       ==  inventDim.inventDimId
             && inventDim.InventLocationId  ==  invId;

    info(strfmt("%1", inventSum.PhysicalInvent)); 


Еще есть макросы для линковки InventDim.

А как же WHERE InventSum.closed =0 ?????

Recoilme

InventSum.closed == NoYes::No

=)