как программно получить список всех наименований / значений у Enum

[oleggy]

Подскажите как зная название только поля таблицы и саму таблицу определить через Job какой Enum используется для данного поля?
А дальше зная этот Enum получить список всех возможных значений этого Enum с наименованием.
Это в рамках Job можно как то получить? Или только вручную

[S.Kuskov]

Перебрать элементы Енум

[oleggy]

А как зная название поля и названия таблицы определить есть ли у этого поля Enum и само enumnum этого енум можно как то получить?

Это нужно разработчикам которые не занимаются AX и лазить по системе не умеют. Хочу Job написать что бы сами могли информацию получать.

[S.Kuskov]

Как получить имя типа расширенного типа

только вам нужен будет не dictField.typeId(), а dictField.enumId() если dictField.baseType() == Types::Enum

[Vadik]

How to see enum values in D365

[wojzeh]

сначала dictField.typeId();
потом:

 public void populateTree()
    {
        DictEnum          policyRuleTypeEnum;
        int               i;
        policyRuleTypeEnum = new DictEnum(enumNum(SysPolicyRuleTypeEnum));


        for(i = 0; i < policyRuleTypeEnum.values(); i++)
        {
            str sym = policyRuleTypeEnum.value2Symbol(i);
            info(strFmt("%1 %2 %3", i, policyRuleTypeEnum.value2Name(i), sym));
        }

    }

[oleggy]

.

[Владимир Максимов]

Цитата:

Сообщение от wojzeh

сначала dictField.typeId();
потом:

 public void populateTree()
    {
        DictEnum          policyRuleTypeEnum;
        int               i;
        policyRuleTypeEnum = new DictEnum(enumNum(SysPolicyRuleTypeEnum));


        for(i = 0; i < policyRuleTypeEnum.values(); i++)
        {
            str sym = policyRuleTypeEnum.value2Symbol(i);
            info(strFmt("%1 %2 %3", i, policyRuleTypeEnum.value2Name(i), sym));
        }

    }

Если уж используешь value2Symbol, тогда в качестве максимального значения счетчика цикла надо ставить 255. Иначе если есть разрывы в значениях, то просто все значения не получишь

Т.е. или в цикле i < policyRuleTypeEnum.values(), но тогда внутри policyRuleTypeEnum.index2Value(i)

Или внутри цикла policyRuleTypeEnum.value2Symbol(i), но тогда в самом цикле I < 255

Для примера, подставь Base Enum с именем UtilElementType. Он как раз на 100 элементах и завершит работу, несмотря на тот факт, что есть значения и больше 100

[oleggy]

Цитата:

Сообщение от Владимир Максимов

в цикле i < policyRuleTypeEnum.values(), но тогда внутри policyRuleTypeEnum.index2Value(i)
Или внутри цикла policyRuleTypeEnum

А как вывести системное название текущего значения Enum если в цикле используешь values() ?
Действительно value2Symbol(i) пишет фигню.

    Name enumName = 'InventTransType';
    DictEnum    dictEnum = new DictEnum(enumName2Id(enumName));
    Name nameLabel, nameSys;
    AnyType enumValue;
    Counter     i;
    ;
    setprefix('Сообщения');

    if (true) // 255
    {
        for (i = 0; i < 255; i++)
        {
            nameLabel = dictEnum.value2Name(i);
            nameSys = dictEnum.value2Symbol(i);
            if (nameSys)
                info(strfmt('%1\t%2 ("%3") = %4', enumName, nameSys, nameLabel, i));
        }
    }
    else // values()
    {
        for (i = 0; i < dictEnum.values(); i++)
        {
            enumValue = dictEnum.index2Value(i);
            //nameSys = dictEnum.value2Symbol(i); // некорректно выводит
            info(strfmt('%1\t%2 = %3', enumName, nameSys, enumValue));
        }
    }

[oleggy]

Цитата:

Сообщение от oleggy

А как вывести системное название текущего значения Enum если в цикле используешь values() ?

Разобрался.

    for (i = 0; i < dictEnum.values(); i++)
        {
            enumValue = dictEnum.index2Value(i);
            nameLabel = dictEnum.index2Label(i);
            nameSymbol = dictEnum.index2Symbol(i);
            info(strfmt('%1\t%2 ("%3") = %4', enumName, nameSymbol, nameLabel, enumValue));
        }