Как программно создать строку номенклатуры???

[Сергей Щербак]

Всем привет! Разбирался с методами создания строки номенклатуры при интерактивном вводе новой номенклатуры. Пытаюсь создать с помощью кода - не хочет добавлять новую строку - меняет текущую. Есть у кого-нить пример как енто проделать???

[niksen]

пробовал этот код использовать в AX 2009, номенклатура не появляется, но создать с таким же именем нельзя, в таблицах SQL она есть. Подскажите, как программно этого добиться в 2009ой версии?

[Ivanhoe]

        inventTable.clear();
        inventTable.initValue();
        inventTable.ItemId              = NumberSeq::newGetNum(InventParameters::numRefItemId(), false).num();
        inventTable.ItemName            = "Название товара"
        inventTable.txtDefault(true, "Описание товара");
        inventTable.DimGroupId  = "Группа аналитик";
        inventTable.ModelGroupId = "Группа моделей";
        inventTable.ItemGroupId= "Группа номенклатуры";

        inventTable.insertInventItemOrderSetup(); // Новые таблицы AX2009

        inventTable.PrimaryVendorId = "" // Код основного поставщика

        inventTable.insert();

        inventItemLocation.clear();
        inventItemLocation.inventDimId = InventDim::inventDimIdBlank();
        inventItemLocation.ItemId      = inventTable.ItemId;
        inventItemLocation.insert();

        inventTableModule.clear();
        inventTableModule.initValue();
        inventTableModule.ModuleType    = ModuleInventPurchSales::Purch;
        inventTableModule.ItemId        = inventTable.ItemId;
        inventTableModule.insert();

        inventTableModule.clear();
        inventTableModule.initValue();
        inventTableModule.ModuleType    = ModuleInventPurchSales::Sales;
        inventTableModule.ItemId        = inventTable.ItemId;
        inventTableModule.insert();

        inventTableModule.clear();
        inventTableModule.initValue();
        inventTableModule.ModuleType    = ModuleInventPurchSales::Invent;
        inventTableModule.ItemId        = inventTable.ItemId;
        inventTableModule.insert();

[AndyD]

Поблема здесь

_inventItemLocation.inventDimId = 'Axapta';

В DAX2009 пустая аналитика называется 'AllBlank', но как правильно написал Ivanhoe, лучше использовать InventDim::inventDimIdBlank()

[niksen]

всё равно ошибки всякие повылезали, начиная от ";" и тд...
помогло вот это, взятое с иностранного сайта

// Created on 06 Jul 2010 by Jovan Bulajic
// This can be called to create a new item from code, for example CreateNewItem('AA01');
static void CreateNewItem(ItemId _itemId, ItemGroupId _itemGroup, ItemName _itemName)
{
    InventTable         inventTable;
    InventTableModule   inventTableModule;
    InventItemLocation  inventItemLocation;
    ;



    ttsbegin;

    // Master record in InventTable
    select forupdate inventTable;
    inventTable.initValue();
    // If InventTable has other mandatory fields in addition to
    // ItemGroupId and ItemId, they should be defined here
    inventTable.ItemGroupId = _itemGroup;
    inventTable.ItemId = _itemId;
    inventTable.ItemName = _itemName;
    inventTable.ItemType = ItemType::Item;
    // You can put default DimGroupId, ModelGroupId, etc. here
    inventTable.insert();

    // InventItemLocation for default dimension
    select forupdate inventItemLocation;
    inventItemLocation.initValue();
    inventItemLocation.ItemId = _itemId;
    inventItemLocation.InventDimId = InventDim::inventDimIdBlank();
    inventItemLocation.insert();

    select forupdate inventTableModule;
    // запасы
    inventTableModule.initValue();
    inventTableModule.ItemId = _itemId;
    inventTableModule.ModuleType = ModuleInventPurchSales::Invent;
    inventTableModule.insert();
    // покупка
    inventTableModule.initValue();
    inventTableModule.ItemId = _itemId;
    inventTableModule.ModuleType = ModuleInventPurchSales::Purch;
    inventTableModule.insert();
    // продажа
    inventTableModule.initValue();
    inventTableModule.ItemId = _itemId;
    inventTableModule.ModuleType = ModuleInventPurchSales::Sales;
    inventTableModule.insert();

    ttscommit;

}

Теперь возникает другой вопрос: как запускать job из job'a с какими-то параметрами?
Вот пример взятый из различных источников:

static void Jobs_MyJob(str _text)
{
;
    info(_text);
}

создали job для запуска, а затем через MenuItem

static void Jobs_ExecutingJob(Args _args)
{
    Args                     args;
;
    args = new Args();
    args.name(identifierStr(Jobs_MyJob));
    new menuFunction(menuItemActionStr(Jobs_MyJob), MenuItemType::Action).run(args);
    
}

но он не работает, выдаёт ошибку на строке "new"
поиск по форуму ничем не помог

[sukhanchik]

Есть самый простой способ создать номенклатуру без лишних табличек:

static void Job10(Args _args)
{
    InventTable          inventTable;
    AxInventTable        axInventTable;
    ItemId                _itemId = 'Ном001';
    ItemName             _itemName = 'Номенклатура 001';
    ;
    axInventTable = AxInventTable::construct();
    axInventTable.parmItemId(_itemId);
    axInventTable.parmItemName(_itemName);
    axInventTable.parmItemGroupId('МояГруппа');
    axInventTable.parmNameAlias(_itemName);
    axInventTable.validateInput(true);
    axInventTable.save();
    inventTable = axInventTable.inventTable();
}

[niksen]

Если писать, как предложил sukhanchik, то надо дописать тогда ещё строчки

axInventTable.parmDimGroupId(_InventDimGroupId);
    axInventTable.parmItemType(ItemType::Item);
    axInventTable.parmModelGroupId(_InventModelGroupId);

Поправьте, если не прав, у меня без этих строчек не заработало

[sukhanchik]

Цитата:

Сообщение от niksen

Если писать, как предложил sukhanchik, то надо дописать тогда ещё строчки

axInventTable.parmDimGroupId(_InventDimGroupId);
    axInventTable.parmItemType(ItemType::Item);
    axInventTable.parmModelGroupId(_InventModelGroupId);

Поправьте, если не прав, у меня без этих строчек не заработало

В целом согласен, но без этих строк у меня номенклатура создалась, поэтому я так и написал (выдрал кусок текста из кода).
Общая идея примера была в том, что в данном случае программисту не нужно заботиться о всяких там InventTableModule / InventItemLocation - связанных таблицах.

PS. Вспомнил - да, у меня номенклатура создалась - т.к. на момент ее создания я поставил validateInput(false) .

[niksen]

интересен теперь другой вопрос, чтобы не плодить множество тем:
как правильно, используя axInventTable выделить нужную запись и обновить её, либо же удалить?
как я понимаю, нужно использовать axInventTable.save для обновления-создания и axInventTable.delete, но как именно выбрать нужную запись и обновить-создать-удалить?

[Ivanhoe]

Наверное, как-то так: AxInventTable::newInventTable(inventTable), где inventTable - курсор с нужной номенклатурой.

[niksen]

вот что-то вроде начала
ItemId='_Болт' в начале, затем

ttsbegin;
              if (InventTable::find(_itemId,true)) ///// проверка на существование записи
                 {
                    select InventTable
                        where InventTable.ItemId == '_Болт';
                        {

                            AxInventTable.inventTable(InventTable);
                            
                        }

вопрос в том, что писать дальше, чтобы изменить данные, простое присвоение через AxInventTable.inventTable.имяПоля = значение не работает, а через parm-методы выдаёт ошибку "объект не инициализирован". Впрочем, ту же ошибку выдаёт, если вместо присвоения стоит AxInventTable.delete();

[ice]

для проверки на существование используейте метод InventTable::exist()

[Ivanhoe]

Это вы так вольно изменили мой вариант? Или вообще его не рассматривали?

[sukhanchik]

У меня совершенно прекрасно работает такой код, независимо от наличия записи в inventTable после отработки find:

    inventTable = InventTable::find(_itemId, true);
    axInventTable = AxInventTable::construct();
    axInventTable.inventTable(inventTable);
    axInventTable.parmItemId(_itemId);
    axInventTable.parmItemName(_itemName);
.....................
    axInventTable.validateInput(true);
    axInventTable.save();
    inventTable = axInventTable.inventTable();

[niksen]

пробовал вместо

 AxInventTable.inventTable(InventTable);
AxInventTable.delete();

AxInventTable::construct();
AxInventTable::newInventTable(InventTable);
AxInventTable.delete();

результат тот же, ошибка объекта не инициализирован

[ice]

вместо

AxInventTable::construct();
AxInventTable::newInventTable(InventTable);
AxInventTable.delete();

надо

axInventTable = AxInventTable::newInventTable(InventTable);
axInventTable.delete();

[niksen]

Ivanhoe
рассматривал, но не заработало, потому что забыл где-то что-то дописать, видимо нельзя работать сонным
sukhanchik
Вариант с find отлично работает
ice
именно так теперь и делаю, забыл, что некоторые вещи нужно вызывать особым способом
всем спасибо