перебор элементов в Tree

[Weez]

Добрый день, господа. Возникла следующая проблема - необходимо перебрать все элементы дерева, начиная с корня и проходя по всем child-элементам. Думаю что это будет какая-то рекурсивная функция, но с реализацией ее пока проблема... Если кто-то сталкивался с подобным - прошу помочь.

[Lemming]

Правда нужна лицензия на crm

PHP код:

static void Tutorial_treeWalk(Args _args)
{

    int             i;
    smmSalesUnit    childSalesUnit;

    void    runTree(smmSalesUnitId      _root = "")
    {
        smmSalesUnit            smmSalesUnit;
        smmSalesUnitMembers     salesUnitMembers;
        ;

        while select salesUnitMembers
            where salesUnitMembers.SalesUnitId == _root
            {

                info(strfmt("Группа: %1, Менеджер: %2", _root,  salesUnitMembers.SalesManId));
                i++;
            }

        while select smmSalesUnit
            where smmSalesUnit.ParentId == _root
        {
            select firstonly childSalesUnit
                where childSalesUnit.ParentId == smmSalesUnit.SalesUnitId;

            if (childSalesUnit.RecId != 0)
            {
                runTree(smmSalesUnit.SalesUnitId);
            }
            else
            {
                while select salesUnitMembers
                    where salesUnitMembers.SalesUnitId == smmSalesUnit.SalesUnitId
                {
                    info(strfmt("Группа: %1, Менеджер: %2", _root,  salesUnitMembers.SalesManId));
                }
            }
        }

    }
    ;
    runTree("");
    info(int2str(i));


} 


[Dudnik Anton]

void rebuildSubnodes(TreeItemIdx _treeItemIdx = FormTreeAdd::Root)
{
    FormTreeItem    treeItem;
    TreeItemIdx     childIdx = treeControl.getChild(_treeItemIdx);

    while (childIdx)
    {
        treeItem = treeControl.getItem(childIdx);
        if (conFind(conCheckedNodes, treeItem.data()))
            treeItem.stateImage(imageListAppl.image(#ImageCheckAll));
        else
            treeItem.stateImage(imageListAppl.image(#ImageCheckNone));
        treeControl.setItem(treeItem);

        if (conFind(conBuiltNodes, treeItem.data()))
            this.rebuildSubnodes(treeItem.idx());

        childIdx = treeControl.getNextSibling(childIdx);
    }
}

[Weez]

Спасибо за ответ, думаю когда-нибудь он пригодится... Я наверно неправильно выразился, нужно было пройтись не по таблице, а по элементам контрола Tree. Решение только что нашел на форуме, ссылка прилагается
Работа с деревом

[Weez]

Как записать значение в Data() элемента formTreeItem?
В моем конкретном случае нужно записать enum, но думаю тут тип не влияет на результат.
Привожу псевдокод: (Tree - элемент дерево на форме)

formTreeItem                          Tmp;
DetailingOfSales                     detailing; //таблица
int                                         curr;

curr = tree.add(parent, 0, detailing.unitId);
Tmp = tree.getItem(curr);
Tmp.data(detailing.UnitType);

После этого заполняется Data() Tmp, но tree.getItem(curr).data() при этом выдает 0
Не знаю что делать, поиск не помог

[AndyD]

Добавьте в ваш код

...
tree.setItem(Tmp);

[AndyD]

Кстати, можно добавлять узлы так

curr = new FormTreeItem(detailing.unitId);
curr.data(map);
tree.addItem(parent, 0, curr);

[Weez]

Благодарю, последний вариант подошел идеально

[user_ax]

Вопрос по деревьям:

Строится отчёт Excel, есть поле Отдел продаж(salesUnitid), там дерево. Нужно сделать выборку по этому полю и чтобы в отчёт попадали те строки, которые соответствуют выбранному уровню, то есть, если выбран отдел продаж, нужно выбирать все строки, которые соответствуют нижнему уровню отдела продаж(БП,РФ,ДЗАт и т.д.), а если выбран один из нижних уровней - строки только нижнего уровня. То есть, чтобы раскрытие дерева шло вниз.

Посоветовали использовать List и в цикле прогонять каждый раз, но не совсем представляю как это сделать, показали пример на cte, но у меня запрос не на чистом sql, а на аксаптовском sql, если можно так выразиться, так что не думаю, что мне cte подойдёт.
Может кто подсказать в какую сторону копать и с чего начинать проход ?
Почитал на форуме ещё, что можно Map-ы использовать для этого дела...
Я так понимаю, по таблице SMMSALESUNIT и сравнивать PARENTID и SALESUNITID , но что-то голова не работает...

Что-то вроде

while select salesunitid  from SmmSalesUnit where .SmmSalesUnit salesunitid like  SmmSalesUnit .parentid
{
List.add(salesunitid);
}

В правильном ли направлении мыслю?

[user_ax]

Никто не может подсказать хотя бы приблизительного решения?

[plumbum]

Ну в общем Вы двигаетесь в правильном направлении.
Если я Вас правлиьно понял, Вам надо выбрать все дочерние записи отталкиваясь от определенного значения SalesUnitId,

тогда напишите рекурсивную функцию, которая, получая SalesUnitId как параметр, выбирает по очереди (while select) все дочерние записи, и, если какая нибудь из них тоже содержит дочерние, вызывается рекурсивно для этой конкретой дочерней записи.

Ну например:

static void Job45(Args _args)
{
    SMMSalesUnitId      salesUnitId;
    List                salesUnits = new List(Types::String);

    List getChildSalesUnit(SMMSalesUnitId _salesUnitIdParent)
    {
        SMMSalesUnit    salesUnit;
        List            childSalesUnit = new List(Types::String);
        
        //Add current sales unit to list
        childSalesUnit.addEnd(_salesUnitIdParent);
        
        //Check for child records
        select count(RecId)
            from salesUnit
            where salesUnit.ParentId == _salesUnitIdParent;

        if (!salesUnit)
        {
            return childSalesUnit;
        }
        //Go through child records and call recurent function
        while select SalesUnitId
            from salesUnit
            where salesUnit.ParentId == _salesUnitIdParent
        {
            //Merge list with the result list of all children
            childSalesUnit = List::merge(childSalesUnit, getChildSalesUnit(salesUnit.SalesUnitId));
        }
        return childSalesUnit;
    }
    ;
    
    salesUnitId = "any value";
    salesUnits  = getChildSalesUnit(salesUnitId);
}

[user_ax]

Цитата:

Сообщение от plumbum

Ну в общем Вы двигаетесь в правильном направлении.
Если я Вас правлиьно понял, Вам надо выбрать все дочерние записи отталкиваясь от определенного значения SalesUnitId,

тогда напишите рекурсивную функцию, которая, получая SalesUnitId как параметр, выбирает поочереди (while select) все дочерние записи, и, если какая нибудь из них тоже содержит дочернии, вызывается рекурсивно для этой конкретой дочерней записи.

Да, вы меня правильно поняли.
Если есть дочерние - выбирать их, если нет - выбирать текущее значение salesunitid, которые выделено.
Сейчас попробую ваш джобик)

[plumbum]

Я прошу прощения, допустил в джобе ошибку. Критерий выборки конечно:

where salesUnit.ParentId == _salesUnitIdParent

в посте выше эта ошибка уже исправлена

[plumbum]

Как я уже написал, джобик я подправил.
Попробуйте так:

print (salesUnits.toString())

[user_ax]

Благодарю, поправил.

Хотел посмотреть дочерние элементы Отдела продаж, но почему-то не вывел, или это необходимо делать в цикле?

    salesUnitId = "Отдел продаж";
    salesUnits  = getChildSalesUnit(salesUnitId);
    print (salesUnitId);
    pause;

[user_ax]

Цитата:

Сообщение от plumbum

Как я уже написал, джобик я подправил.
Попробуйте так:

print (salesUnits.toString())

Да, это то, что мне нужно, по идее. Как элементы указанного уровня так и дочерние. Теперь буду мудрить , дабы прикрутить это к моему запросу!

[plumbum]

Можно про запрос по-подробнее?
Ели вам нужен этот список, как источник данных, переберите весь List итератором/энумератором, и повставляейте записи во временную таблицу. Тогда я еще бы посоветовал создавать List с типом элементов Record: не пришлось бы потом по ключу перевыбирать записи.

Удачи!

[user_ax]

Цитата:

Сообщение от plumbum

Можно про запрос по-подробнее?
Ели вам нужен этот список, как источник данных, переберите весь List итератором/энумератором, и повставляейте записи во временную таблицу. Тогда я еще бы посоветовал создавать List с типом элементов Record: не пришлось бы потом по ключу перевыбирать записи.

Удачи!

Мой запрос выбирает записи из нескольких таблиц по конкретным параметрам, один из них - элемент из Отдела продаж(smmsalesunitid).
По поводу enumerator читал, попробую, спасибо.

Вы имеете ввиду Types::Record ?

[user_ax]

Теперь проблема иного характера.

Рекурсивный метод отрабатывает верно и выбирает все дочерние значения по отношению к выбранному.
Объявил строковую переменную в методе выборки данных, присвоил ей результат, который возвращает метод (строка строк), в условии выборки пишу

salesQuotationTable.SalesUnitId like salesunitid

в salesunitid у нас

<"Отдел продаж трансф.", "БП", "ДЗАТ", "ДЗБВА", "ДЗЕА", "РФ", "СРАЗ", "УБМ">

Но запрос не отрабатывает в принципе, если убрать условие с лайком, то запрос отрабатывает и отчёт строится, но по неверным данным.

Есть ли какие-то особенности лайка аксаптовского? Искал на форуме, ничего толкового не нашёл. Переменная, в которую попадает результирующая строка ограничена 500 символами.

Буду благодарен за любую подсказку

[S.Kuskov]

Цитата:

Сообщение от user_ax

в salesunitid у нас

<"Отдел продаж трансф.", "БП", "ДЗАТ", "ДЗБВА", "ДЗЕА", "РФ", "СРАЗ", "УБМ">

Чего прям все сразу, в одной строке? LIKE так не умеет.

Так умеет QueryBuildRange