Workflow в realtime можно выполнить в AX2012?

[lvan]

для конкретной записи?
т.е. чтобы не ждать выполнения batch

[AndyD]

Смотрите в строну формы Tutorial_WorkflowProcessor

[lvan]

там тоже через batch вроде

[johny77]

Может это поможет...

PHP код:

static void WF_runRecord(Args _args)
{
    WorkflowMessageBatchAffinity        affinity = str2guid('');
    WorkflowMessageTable                workflowMessageTable;
    Common                              common;
    Int                                 iCnt;
    ;
    // определяем документ для которого стартуем подвисшие шаги согласования
    common = RContractTable::findRecId(0);

    // сбрасываем Affinity (родственное сходство/свойство)
    ttsBegin;
    while select forupdate workflowMessageTable
        where  workflowMessageTable.WorkflowContextRecId    == common.RecId
            && workflowMessageTable.WorkflowContextTableId  == common.TableId
            //&& workflowMessageTable.WorkflowContextCompanyId == common.dataAreaId
            && workflowMessageTable.MessageLifeCycleState == WorkFlowMessageLifeCycleState::Queued
            && workflowMessageTable.batchaffinity != affinity
    {
        workflowMessageTable.batchaffinity = affinity;
        workflowMessageTable.update();

        iCnt ++;
    }
    ttsCommit;

    affinity = newguid();
    while (SysWorkflowMessageQueueTask::assignBatchAffinityRecord(affinity, common.TableId, common.RecId) > 0)
    {
        SysWorkflowEventDispatcher::dispatch(affinity);
    }
} 


[iCloud]

Цитата:

Сообщение от lvan

для конкретной записи?
т.е. чтобы не ждать выполнения batch

Привет, а можно поинтересоваться зачем?

[gl00mie]

Написано же - чтоб не ждать выполнения batch
Чуть адаптировал пример кода к AX 2012 R3, получилось вот что:

WorkflowMessageBatchAffinity    available = emptyGuid();
WorkflowMessageBatchAffinity    affinity;
SysWorkflowMessageTable         messageTable;
Common                          common;
int64                           recs;
;
// определяем документ для которого стартуем подвисшие шаги согласования
common = RContractTable::findRecId(0);
if (!common.RecId)
{
    warning(Error::missingRecord(funcName()));
    return;
}
// сбрасываем Affinity
messageTable.readPast(true);
ttsBegin;
update_recordSet messageTable
    setting BatchAffinity = available
    where   messageTable.WorkflowContextRecId   == common.RecId
        &&  messageTable.WorkflowContextTableId == common.TableId
        &&  messageTable.MessageLifeCycleState  == WorkFlowMessageLifeCycleState::Queued
        &&  messageTable.BatchAffinity          != available
            ;
recs = messageTable.RowCount();
ttsCommit;
affinity = newGuid();
while (true)
{
    ttsBegin;
    update_recordSet messageTable
        setting BatchAffinity = affinity
        where   messageTable.WorkflowContextRecId   == common.RecId
            &&  messageTable.WorkflowContextTableId == common.TableId
            &&  messageTable.MessageLifeCycleState  == WorkFlowMessageLifeCycleState::Queued
            &&  messageTable.BatchAffinity          == available
                ;
    recs = messageTable.RowCount();
    ttscommit;
    if (recs == 0)
    {
        break;
    }
    SysWorkflowQueue::dispatch(affinity);
}

[Ivanhoe]

RContractTable в 2012 ммм