map+map

[Aslan]

Каким образом можно сложить значения 2-ух карт...если известно что их ключи идентичны....?

[Gad]

сложить - это как? При совпадении ключа value + value? а value какого типа?

[Aslan]

key - str
value - integer

[Aslan]

то есть получить карту с такими же ключами и суммой value?

[EVGL]

А как насчет не Map, а класса KeySum?

[Aslan]

значит...не стоит свечь?

[Roman777]

Вот так должно работать:

PHP код:

static void Job11(Args _args)
{
    map         mapSource1  = new Map(Types::String, Types::Integer);
    map         mapSource2  = new Map(Types::String, Types::Integer);
    map         mapDest     = new Map(Types::String, Types::Integer);
    MapIterator mi;
    ;

    // .. некая инициализация  mapSource1, mapSource2 -->
    // ..
    // .. некая инициализация  mapSource1, mapSource2 <--


    mi = new mapIterator(mapSource1);
    mi.begin();
    while (mi.more())
    {
        if (mapSource2.exists(mi.key()))
        {
            mapDest.insert(mi.key(), mi.value() + mapSource2.lookup(mi.key()));
        }
        mi.next();
    }
} 


[Gad]

Боюсь, что кроме перебора mapa никак.

[Aslan]

спасибо всем хоть так можно

[user_ax]

Заранее прошу прощения за поднятие темы.
Нужен почти тот же результат, только вместо сложений значений map-ов, нужно добавить элементы вторго мепа к элементам первого.
То есть, например:
Есть map1 из 7 элементов;
Есть map2 из 5 элементов;

Хочу получить map3, который будет состоять из 12 элементов.
Это возможно ?
Заранее спасибо за ответы!!

[plumbum]

А что делать, с теми элементами, где ключи пересекаются?

Посмотрите еще здесь:
Классы коллекции

[user_ax]

Цитата:

Сообщение от plumbum

А что делать, с теми элементами, где ключи пересекаются?

Посмотрите еще здесь:
Классы коллекции

А ключи не могут пересекаться ибо в ключе есть tableId, он может измениться только при изменении базы данных ведь. Над этой ситуацией не думал... Весь день сижу уже мудрю..
Можно ещё запаковать оба мепа в контейнер и тогда надо подумать, как сложить 2 контейнера.

Ссылку посмотрю сейчас, спасибо!

[db]

Нечего тут голову ломать
1. Если ключи не пересекаются - так и сохраняйте сразу в одном. Например, передавайте ссылку на мап через параметр в метод, добавляющий в них элементы вместо складывания результирующих мапов. Вот час назад писал как раз такое

private Map calcJournalLines(mInventRejectJournalTable _journalTable,
                             InventTable               _inventTable,
                             mProgressBarNoTotals      _bar)
{
    Map     journalLines = new Map(Types::String, Types::Container);
    ;
    this.calcInventTrans(_journalTable, _inventTable, _bar, journalLines);
    this.calcInventSettlements(_journalTable, _inventTable, _bar, journalLines);

    return journalLines;
}

Или в двух - один как сейчас, второй общий - там где вставляем в частный мап дублируем вставку еще и в общий.

2. Очевидный и правильный путь - обойти один мап и вставить во второй
3. Трюк с перепаковкой и сложение контейнеров то-же возможен, но это именно трюк. Сложного, как мне помнится, там ничего нет - кроме самих данных там будет еще заголовок из, боюсь соврать, трех элементов. На форуме была тема со структурой упакованных мапов, сетов и т.д.
4. А может вам и не мап нужен?

У всех способов очевидные достоинства и недостатки, но если вы по любым причинам склоняетесь к п.3, то скорее всего с алгоритмом что то не то и стоит об этом серьезно подумать

[Player1]

У map-ов есть есть keyset() и valueset(), а они умеют так:
- set intersection (set1, set2) - возвращает пересечение двух указанных множеств, то есть множество, содержащее элементы, найденные в обоих множествах.
- set union (set1, set2) - возвращает объединение двух указанных множеств, то есть множество содержит значения из обоих множеств.
- set difference (set1, set2) - возвращает множество, содержащее значения множества set1, не найденные в множестве set2.
© Шашков Р., Еременко А.

[db]

Цитата:

Сообщение от Player1

У map-ов есть есть keyset() и valueset(), .

Только если надо сложить ключи и значения отдельно. Это не поможет получить общий мап

[user_ax]

Цитата:

Сообщение от db

4. А может вам и не мап нужен?

У всех способов очевидные достоинства и недостатки, но если вы по любым причинам склоняетесь к п.3, то скорее всего с алгоритмом что то не то и стоит об этом серьезно подумать

Может и не нужен. Сейчас подумаю, как алгоритм поменять. Использовал мапы так как нужен уникальный идентификатор, вернее связка 2-х полей для идентификации данных в результирующем наборе данных. А если есть такой же ключ - производить сумму количеств из полей...другого, более изящного решения не придумал.

[plumbum]

Два мапа нужно вам из-за того, что вы их в разных местах инициализируете, или для какого-то логического разделения элементов.
Ведь если вопрос только в инициализации, то можно выкрутиться и создать один мап. Передавайте общий мап как параметр в ваши методы и возвращайте его, как результат. Тогда сможете добавить нужные элементы в один мап в нескольких местах еще и от дубликатов избавитесь.
Ну а если честно, сколько элементов в сумме в двух мапах получается? Может стоит уже их просто перебрать

[user_ax]

Цитата:

Сообщение от plumbum

Два мапа нужно вам из-за того, что вы их в разных местах инициализируете, или для какого-то логического разделения элементов.
Ведь если вопрос только в инициализации, то можно выкрутиться и создать один мап. Передавайте общий мап как параметр в ваши методы и возвращайте его, как результат. Тогда сможете добавить нужные элементы в один мап в нескольких местах еще и от дубликатов избавитесь.
Ну а если честно, сколько элементов в сумме в двух мапах получается? Может стоит уже их просто перебрать

Разделяю скорее всего. У меня есть результирующий набор данных из Query(4 таблицы). 2 таблицы я пихаю в 1 мап по уникальному ключу(номенклатура+номер спецификации), вторые 2 таблицы я пихаю в другой мап по этому же ключу. Если ключ в мапе есть - я делаю суммирование кол-ва, иначе произвожу вставку в меп.
А по поводу метода с мапом в кач-ве параметра не совсем понял, если честно.

Данным методом я создаю своих 2 мапа

void FindSpecForClose()
{
    //view variable ->
    JourListTrans       jour,list;
    InvoiceInvent       invoice,invent;
    //<-
    str                     listKey,
                            invoiceKey;
    container               listCon,
                            invoiceCon;
    ;
    ListMap = new Map(Types::String, Types::Container);
    InvoiceMap = new Map(Types::String, Types::Container);

    //->add range in query by date
    if(bydate)
        queryRun.query().dataSourceNo(1).addRange(fieldnum(JourListTrans,SpDate)).value(strFmt('(SpDate <= %1)', date2strXpp(bydate)));
    
    //<-
    //info(queryRun.query().dataSourceNo(1).toString());
    
    while(queryRun.next())
    {
        jour = queryRun.get(tablenum(JourListTrans));
        list = queryRun.get(tablenum(JourListTrans));
        invoice = queryRun.get(tablenum(InvoiceInvent));
        invent = queryRun.get(tablenum(InvoiceInvent));


        listKey = list.InternalSp + "#" + list.ItemId+"#"+tablenum(VendSpListTrans);

        invoiceKey = invoice.InternalSp + "#" + invoice.ItemId+"#"+tablenum(VendInvoiceTrans);

        //check in vendSpListTrans
        if(ListMap.exists(listKey))
        {
            listCon = ListMap.lookup(listKey);
            listCon = conpoke(listCon,7,conpeek(listCon,7)+list.SumOfSpQty);
            listMap.insert(listKey,listCon);
        }
        else
        {
            listMap.insert(listKey,[jour.IDSp, jour.SpDate, jour.RContractAccount,list.InternalSp, list.ItemId, list.SpUnit, list.SumOfSpQty]);
        }
        //check in VendInvoiceTrans
        if(InvoiceMap.exists(invoiceKey))
        {
            invoiceCon = invoiceMap.lookup(invoiceKey);
            invoiceCon = conpoke(invoiceCon,3,conpeek(invoiceCon,3)+invoice.SumOfQty);
            InvoiceMap.insert(invoiceKey,invoiceCon);

        }
        else
        {
            invoiceMap.insert(invoiceKey,[invoice.ItemId, invoice.PurchUnit, invoice.SumOfQty, invoice.InternalSp, invent.UnitId]);
        }

    }
}

Если есть какой-либо другой путь решения - я с удовольствием узнаю о нём. Сейчас пока что пришла идея лишь заменить мепы на общий контейнер

[S.Kuskov]

Цитата:

Сообщение от user_ax

Разделяю скорее всего.

А для чего вы их разделяете? Вы их перед объединением ещё как-то по разному обрабатываете?

[user_ax]

Цитата:

Сообщение от S.Kuskov

А для чего вы их разделяете? Вы их перед объединением ещё как-то по разному обрабатываете?

Так данные-то разные, для того и разделяю.
Объединение ещё как такового нет, но перед объединением, да, обрабатываю, а именно: провожу сверку единиц измерения и проверяю равенство сумм.