Query.pack()

[ice]

Странный результат выдает операция pack/unpack в Query

static void testQueryPack(Args _args)
{
    Query                q1, q2;
    QueryBuildDataSource qbds1, qbds2;
    container            con;
    ;
    q1    = new Query();
    qbds1 = q1.addDataSource(tablenum(InventTrans));
    qbds1.addRange(fieldnum(InventTrans, StatusIssue)).value(queryValue(StatusIssue::Sold));
    qbds1.addRange(fieldnum(InventTrans, StatusReceipt)).value(queryValue(StatusReceipt::Purchased));
    qbds1.addRange(fieldnum(InventTrans, StatusReceipt)).value(queryValue(StatusReceipt::None));
    qbds1.addRange(fieldnum(InventTrans, StatusIssue)).value(queryValue(StatusIssue::None));
    info(qbds1.toString());
    con = q1.pack();
    q2  = new Query(con);
    qbds2 = q2.dataSourceTable(tablenum(InventTrans));
    info(qbds2.toString());
}

чем это можно объяснить?

[kashperuk]

Да, действительно, похоже на какой-то глюк.

Попробуйте может через

    con = SysQuery::packRangeAndSortorder(q1);
    SysQuery::unpackRangeAndSortorder(q2, con);

Правда это сработает для этой конкретной ситуации, но может не сработать для более общей

[AndyD]

Навскидку - StatusIssue::None и StatusReceipt::None не имеют меток (label). Если их создать, то Query из контейнера будет создаваться нормально

[kashperuk]

Цитата:

Сообщение от AndyD

Навскидку - StatusIssue::None и StatusReceipt::None не имеют меток (label). Если их создать, то Query из контейнера будет создаваться нормально

Точно.
Если вместо None указать другое значениЕ, то будет ОК

[ice]

придется давать осмысленный label, типа "Нет"

[ice]

в Ax 2009 этот баг так и не исправили

ПС причем, если в трешке можно было в Label поставить пробел для решения данной проблемы, то в Ax 2009 так сделать нельзя

[kashperuk]

Я думаю, что его и не исправят в обозримом будущем. Так что стоит принять это как должное, и указывать метки для всех перечислений.

[ice]

Цитата:

Сообщение от kashperuk

Я думаю, что его и не исправят в обозримом будущем. Так что стоит принять это как должное, и указывать метки для всех перечислений.

еще бы МС так делал, совсем было бы прекрасно

[Denicce]

Можно так сделать. Хоть какое-то "удобство".

новый метод \Classes\Global\queryValueEnum

static str queryValueEnum(int _value, Name _dsName, FieldName _fieldName)
{
    return strfmt("(%1.%2 == %3)", _dsName, _fieldName, _value);
}

static void testQueryPack(Args _args)
{
    Query                q1, q2;
    QueryBuildDataSource qbds1, qbds2;
    container            con;
    ;
    q1    = new Query();
    qbds1 = q1.addDataSource(tablenum(InventTrans));

    qbds1.addRange(fieldnum(InventTrans, StatusIssue)).value(queryValueEnum(StatusIssue::None, qbds1.name(), "StatusIssue"));
    qbds1.addRange(fieldnum(InventTrans, StatusIssue)).value(queryValueEnum(StatusIssue::Sold, qbds1.name(), "StatusIssue"));

    qbds1.addRange(fieldnum(InventTrans, StatusReceipt)).value(queryValueEnum(StatusReceipt::None,      qbds1.name(), "StatusReceipt"));
    qbds1.addRange(fieldnum(InventTrans, StatusReceipt)).value(queryValueEnum(StatusReceipt::Purchased, qbds1.name(), "StatusReceipt"));

    info(qbds1.toString());
    con = q1.pack();
    q2  = new Query(con);
    qbds2 = q2.dataSourceTable(tablenum(InventTrans));
    info(qbds2.toString());
}

[Logger]

Пожалуй все же проще было бы задать метки для всех значений енумов.
Где-то на форуме даже выкладывали джоб, для поиска таких значений.