Смена первичного ключа таблицы VendTable

[Masterofmind]

Доброго дня, коллеги.

Сразу извиняюсь за возможный оффтоп, но очень срочно нужен совет гуру. При импорте первичных данных в систему (DAX 4.0 SP2 - 3-х звенка) был допущен один промах, а именно - в кодах поставщиков присутствуют и латинская и русская буква С. Задача - перекодировать все первичные ключи и заменить (где присутствует) латинскую С на русскую С.
Формат кода - XXСПYYYYYYY, где XX-код подразделения за которым числится поставщик, а YYYYYYY - порядковый номер формата 0000021

Я имею очень скромный опыт программирования в DAX, вот попытался написать, который все это дело исправляет:

static void Base1000_RenameVendPrKey(Args _args)
{
    vendTable        vendTable,
                     findVendTable;

    str              strToUpdate;
    ;

    while select recid from vendTable
        where vendTable.AccountNum like "*C*"
    {
        try
        {
            ttsbegin;

            findVendTable = VendTable::findRecId(vendTable.RecId, true);

            if(findVendTable)
            {
                strToUpdate = strpoke(vendtable.AccountNum, "С", strfind(vendtable.AccountNum,"C", 1, strlen(vendtable.AccountNum)));

                CCPrimaryKey::renamePrimaryKey(VendTable, strToUpdate, fieldNum(VendTable, AccountNum)); // переименование во всех связанных таблицах

                VendTable.AccountNum = strToUpdate ;

                VendTable.renamePrimaryKey(); // переименование в основной таблице

                //VendTable.update();
            }

            ttscommit;
        }
        Catch (exception::error)
        {
             exceptionTextFallThrough(); // вывод ошибки

             ttsabort;
             retry; // повтор блока try
        }
    }
}

Джоб почему-то не работает, или вылетает с ошибкой, которую я перехватить не могу. Ошибка я так понимаю идет из-за блокировки таблицы.
По идее я хочу перехватывать ошибку блокировки и пытаться апдейтить следующую запись, и таким образом - путем нескольких итераций привести справочник к "употребляемому" руководством виду.

Ваше мнение господа? Помогите провести аудит кода и подскажите, ЧТО именно я не так делаю.

[twilight]

Почему обновляете VendTable, а не findVendTable?

[mazzy]

и метод renamePrimaryKey есть на самой таблице.
лучше вызывать сразу
findVendTable.renamePrimaryKey();
не заморачиваясь на CC*-классы.

кроме того, не вызывайте renamePrimaryKey если код не изменился. Это очень тяжелый метод.

[Masterofmind]

Насколько я понял из скудного описания - метод CCRenamePrimaryKey - производит поиск обновляет ссылки во всех связанных проводках, если я не буду его использовать, сохраню ли целостность данных?

[mazzy]

Цитата:

Сообщение от Masterofmind

метод CCRenamePrimaryKey - производит поиск обновляет ссылки во всех связанных проводках

этим занимается метод renamePrimaryKey на самой таблице.

семейство классов CC* - обертка над работой с таблицами из интерфейса пользователя. Если вы пишете код, то использовать CC* - избыточно. Работайте с методами таблицы напрямую.

[mazzy]

Цитата:

Сообщение от Masterofmind

CCRenamePrimaryKey - производит поиск обновляет ссылки во всех связанных проводках

Кстати, посмотрел CCPrimaryKey::renamePrimaryKey
он как раз не занимается связанными таблицами.
он обновляет только одну указанную таблицу.

юзайте специальный метод на таблице.

[Masterofmind]

Ок, я понял. Так будет правильно?

strToUpdate = strpoke(vendtable.AccountNum, "С", strfind(vendtable.AccountNum,"C", 1, strlen(vendtable.AccountNum)));
        
                findVendTable.renamePrimaryKey()
                VendTable.AccountNum = strToUpdate ;
                findVendTable.renamePrimaryKey();
               
                findVendTable.update();

Строго не судите, это мой первый джоб, да и программированием я не занимался уже лет 5

[mazzy]

Цитата:

Сообщение от Masterofmind

Ок, я понял. Так будет правильно?

strToUpdate = strpoke(vendtable.AccountNum, "С", strfind(vendtable.AccountNum,"C", 1, strlen(vendtable.AccountNum)));
        
                findVendTable.renamePrimaryKey()
                VendTable.AccountNum = strToUpdate ;
                findVendTable.renamePrimaryKey();
               
                findVendTable.update();

Строго не судите, это мой первый джоб, да и программированием я не занимался уже лет 5

не renamePrimaryKey используется вместо update.

правильно так (в аксапте не проверял)

static void Base1000_RenameVendPrKey(Args _args)
{
    vendTable        vendTable,
                     findVendTable;

    str              strToUpdate;
    ;

    while select recid from vendTable
        where vendTable.AccountNum like "*C*" // тут будет TableScan, ну и черт с ним: все равно надо обработать все записи
    {
        ttsbegin;

        findVendTable = VendTable::findRecId(vendTable.RecId, true);
        if(!findVendTable) continue;

        strToUpdate = strReplace(findVendTable.AccountNum, "С", "C"); // это из класса Global
        if( strToUpdate == findVendTable.AccountNum ) continue;

        findVendTable.AccountNum = strToUpdate;
        findVendTable.renamePrimaryKey(); // переименование во всех связанных таблицах

        ttscommit;
    }
}

ну, и конечно, стоит двадцать раз подумать прежде чем комиттить каждую запись.
в принципе транзакции получаются маленькими и но зафиксироваться может промежуточное состояние, когда обновлены не все записи. Если устраивает, то все нормально.

кроме того, поскольку вы меняете первичный ключ, то теоретически может случится ошибка дублирования уникального индекса...

ну и наконец, чтобы работала комбинация Ctrl+Break стоит добавить ProgressBar

static void Base1000_RenameVendPrKey(Args _args)
{
    vendTable        vendTable,
                     findVendTable;

    str              strToUpdate;
    SysOperationProgress progress;
    ;

    select count(recid) from vendTable;
    progress = SysOperationProgress::newGeneral('','',vendTable.recid); // тут будет больше, чем будет обсчитано.
    // Ну и ладно. Запускать два раза tableScan не будем.

    while select recid from vendTable
        where vendTable.AccountNum like "*C*" // тут будет TableScan, ну и черт с ним: все равно надо обработать все записи
    {
        progress.inccount();
        ttsbegin;

        findVendTable = VendTable::findRecId(vendTable.RecId, true);
        if(!findVendTable) continue;

        strToUpdate = strReplace(findVendTable.AccountNum, "С", "C"); // это из класса Global
        if( strToUpdate == findVendTable.AccountNum ) continue;

        findVendTable.AccountNum = strToUpdate;
        findVendTable.renamePrimaryKey(); // переименование во всех связанных таблицах

        ttscommit;
    }
}

[Masterofmind]

Commit я использую для того, чтобы в случае глобальной ошибки не откатывалась все транкзакция( мое предположение, что будет откачена вся транкзакция). Опыта маловата и недостаток знаний приходится компенсировать воображением и предполагать... такой подход пусть и длительней - зато дает гарантию - что проапдейтились все записи, до возникновения исключающей ошибки. Для меня важен результат, а это - правильно пропатчинные справочник и проводки.

[mazzy]

Кстати, заметил еще одну багу в вашем коде.

Цитата:

Сообщение от Masterofmind

    ...select recid from vendTable...
    ...
    ...strToUpdate = strpoke(vendtable.AccountNum...

обратите внимание, что в селекте вы выбираете только recid.
поэтому использовать потом AccountNum бесполезно - там всегда будет пустое значение.

[mazzy]

Цитата:

Сообщение от Masterofmind

Commit я использую для того, чтобы в случае глобальной ошибки не откатывалась все транкзакция( мое предположение, что будет откачена вся транкзакция). Опыта маловата и недостаток знаний приходится компенсировать воображением и предполагать... такой подход пусть и длительней - зато дает гарантию - что проапдейтились все записи, до возникновения исключающей ошибки. Для меня важен результат, а это - правильно пропатчинные справочник и проводки.

ваше предположение правильно.
но в этом джобе вы можете получить промежуточное состояние - часть записей уже обновлена, а часть - не обновлена.
Если это не ошибка, то все нормально.

[gl00mie]

Цитата:

Сообщение от mazzy

правильно так (в аксапте не проверял)

static void Base1000_RenameVendPrKey(Args _args)
{
        // ...
        findVendTable.AccountNum = strToUpdate;
        findVendTable.renamePrimaryKey(); // переименование во всех связанных таблицах
}

И еще не забудьте, что есть еще такие вещи, как LedgerJournalTrans с ее AccountNum/OffsetAccount, которые могут содержать коды еще и из другой компании, и после штатного "переименования во всех связанных таблицах" строки журналов ГК с соотв.кодами поставщиков у вас могут "отвалиться" от VendTable. На CustTable вроде пытались это лечить, но, как всегда, криво, в частности, без учета того, что CustTable та же может быть в виртуальной компании; где-то вроде об этом уже писали... В общем, не все так просто