Ну уже не знаю что и как делать ((

[kalex_a]

Уважаемы гуру, прошу посмотрите код. Что в нем не так. Ну ни как не могу скорректировать налог ((. Выдает ошибку и все тут .

switch (rDeferralsJournalTrans.DocumentStatus)
    {
        case DocumentStatus::Invoice :
             purchFormLetter = PurchFormLetter::construct(DocumentStatus::Invoice);
             break;
        case DocumentStatus::Facture_RU :
             purchFormLetter = PurchFormLetter::construct(DocumentStatus::Facture_RU);
             break;
    }
    purchFormLetter.specQty(PurchUpdate::ReceiveNow);
    purchParmTable.clear();
    purchFormLetter.createParmTable(purchParmTable,purchTable);
    purchParmTable.ParmId = purchFormLetter.parmId();
    purchParmTable.TransDate = systemDateGet();
    purchParmTable.DocumentDate = systemDateGet();
    purchParmTable.Num = rDeferralsJournalTrans.DocumentNum;
    purchParmTable.FactureExternalId_RU = rDeferralsJournalTrans.DocumentNum;
    purchParmTable.insert();
    purchFormLetter.createParmLine(purchLine);
    ttsbegin;
    select forupdate * from purchParmLine
        where purchParmLine.OrigPurchId==rDeferralsJournalTrans.PurchId &&
              purchParmLine.ParmId==purchFormLetter.parmId();
 
    purchParmLine.initFromPurchLine(purchLine);
    purchParmLine.initFromParmTable(purchParmTable);
    purchParmLine.LineAmount=rDeferralsJournalTrans.AmountCur;
    purchParmLine.update();
    ttscommit;
    purchFormLetter.createParmUpdate();
    purchParmUpdate = purchFormLetter.purchParmUpdate();
    purchParmUpdate.SumBy = AccountOrder::None;
    purchParmUpdate.SpecQty = purchFormLetter.specQty();
    purchParmUpdate.DocumentStatus = purchFormLetter.documentStatus();
    purchParmUpdate.update();
 
    purchFormLetter.purchParmUpdate(purchParmUpdate);
    purchTotals = PurchTotals::construct(purchTable,
                                         PurchUpdate::ReceiveNow,
                                         AccountOrder::None,
                                         purchFormLetter.parmId(),
                                         purchTable.PurchId,
                                         purchFormLetter.documentStatus());
    purchTotals.calc();
    taxRegulation = TaxRegulation::newTaxRegulation(purchTotals.tax());
    taxRegulation.allocateAmount(rDeferralsJournalTrans.TaxAmount);
    taxRegulation.saveTaxRegulation();
    purchFormLetter.initParameters(purchParmUpdate,PrintOut::Current,NoYes::No,NoYes::No,NoYes::No);
    purchFormLetter.run();

[Ivanhoe]

А в выборку попадает несколько закупок? Такая ошибка происходит когда обрабатывается несколько закупок и есть коррекция налога на одной из них. Если делать "руками" в интерфейсе, то ДО коррекции налогов нужно нажать кнопку "Упорядочить" в форме обработка накладной и после этого делать коррекцию. Может, в коде нужно явно вызвать упорядочивание?

[ZVV]

Цитата:

Сообщение от Ivanhoe

А в выборку попадает несколько закупок? Такая ошибка происходит когда обрабатывается несколько закупок и есть коррекция налога на одной из них. Если делать "руками" в интерфейсе, то ДО коррекции налогов нужно нажать кнопку "Упорядочить" в форме обработка накладной и после этого делать коррекцию. Может, в коде нужно явно вызвать упорядочивание?

Да нет, не похоже...
К тому же судя по коду там одна закупка, более того - одна строка по закупке, в накладной.
Вопрос даже скорее по функционалу налогов, чем по программированию.

[kalex_a]

если вызвать purchFormLetter.Prompt() то все срабатывает ((, но мне не надо вызывать эту форму

[ZVV]

Цитата:

Сообщение от kalex_a

если вызвать purchFormLetter.Prompt() то все срабатывает ((, но мне не надо вызывать эту форму

Как вариант:

Ставите брейкпоинт на info.add(), либо ищете где используется метка по вашему сообщению.
Находите нужное место, откуда идёт данное сообщение.
Проясняете для себя причины, почему оно возникает.
Ищете код, который эти причины устраняет (вероятно в стеке prompt() что-то с этим делается).
Копируете в свой код.

[Sada]

В промпте вроде как вызывается метод initLinesQuery(), где заполняются parmTable parmLine и иже с ними. Я бы не стал создавать эти таблы руками и тем более апдейтить их потом. Вместо промпта вызовите ряд методов, которые в нем вызываются и добавьте какой нить параметр типа showdialog, чтоб вызывать purcheditLines или нет. По умолчанию естественно он должен быть true. выже в свой парм метод передавайте false. Возможно этот способ Вам не поможет, но будет более правильным на мой взгляд.

[Sada]

Что то вроде

salesFormLetter = SalesFormLetter::construct(DocumentStatus::Invoice);
        parmId          = salesFormLetter.parmId();
        salesFormLetter.salesTable(salesTable);
        salesFormLetter.getLast();
        salesFormLetter.parmId(parmId);
        salesFormLetter.transDate(salesTable.InvoiceDate);
        salesFormLetter.specQty(SalesUpdate::All);
        salesFormLetter.createParmUpdate();
        salesFormLetter.createParmTable(salesParmTable, salesTable);
        salesFormLetter.initLinesQuery();
        salesFormLetter.run();

Нашол у себя в приложении кусок кода. Для примера. ЗЫ: Плюс передайте свои параметры дополнительно и может что получится.

[kalex_a]

в методе purchFormLetter.run() есть строка

 if (reArrangeNow)
        this.reArrange(false, false);

так вот переменная reArrangeNow имеет значение "true" соответственно выполняется метод this.reArrange(false, false); где выходит на ошибку

if (!this.checkTaxWorkRegulation())
        throw error("@SYS21628");

, а если разносить через форму заказа ("Разноска" -> "Накладная" и т.д.) то она имеет значение "False".

[Sada]

\Classes\FormLetter\reArrangeNow
поставьте тут точку останова

[ZVV]

Цитата:

Сообщение от kalex_a

в методе purchFormLetter.run() есть строка

 if (reArrangeNow)
        this.reArrange(false, false);

так вот переменная reArrangeNow имеет значение "true" соответственно выполняется метод this.reArrange(false, false); где выходит на ошибку

if (!this.checkTaxWorkRegulation())
        throw error("@SYS21628");

, а если разносить через форму заказа ("Разноска" -> "Накладная" и т.д.) то она имеет значение "False".

Ну вот вы и нашли ответ.
Вероятно, метод purchFormLetter.reArrangeNow(false) перед run вам должен помочь.

[Sada]

Цитата:

Сообщение от ZVV

Ну вот вы и нашли ответ.
Вероятно, метод purchFormLetter.reArrangeNow(false) перед run вам должен помочь.

не не не. Помоему так низя. Нада посмотреть почему при стандартной оброботке эта переменная false

[kalex_a]

Цитата:

Сообщение от ZVV

Ну вот вы и нашли ответ.
Вероятно, метод purchFormLetter.reArrangeNow(false) перед run вам должен помочь.

Странно, раньше не работало. Сейчас сработало .

Спасибо ZVV

[Sada]

В методе reArrange выполняется ацкое количество кода Может он там зачем то нужен

[Ivanhoe]

Может, в настройках модуля РП стоит Суммарная обработка = Нет, и этот параметр автоматически подтягивается в форму обработки накладной. А когда вы делаете все из кода, то не прописываете, что суммарной обработки не будет, вот и ошибка.

[kalex_a]

Цитата:

Сообщение от Sada

В методе reArrange выполняется ацкое количество кода Может он там зачем то нужен

Согласен, как я понял ( по моим раскопкам ), он выполняется когда "Суммарная обработка" не равно "Нет", а т.к. у меня всегда равно "Нет", то мне он не нужен

[kalex_a]

Цитата:

Сообщение от Ivanhoe

Может, в настройках модуля РП стоит Суммарная обработка = Нет, и этот параметр автоматически подтягивается в форму обработки накладной. А когда вы делаете все из кода, то не прописываете, что суммарной обработки не будет, вот и ошибка.

Вы правы, хотя я в передаю параметр

purchParmUpdate.SumBy = AccountOrder::None;

но такое чуство что он его не видит

[Ivanhoe]

Эх, залезаем в код

В методе init формы обработки есть строки:

sumBy.selection(purchEditLinesForm.sumBy());
    element.sumByChanged(true);

Первая задает значение параметра SumBy. Вы явно делаете

purchParmUpdate.SumBy = AccountOrder::None;

, т.е. аналогично.

Но во второй строке запускается метод в котором:

if (_init && purchParmUpdate.SumBy == AccountOrder::None)
        reArrangeNow = false;

т.е. еще явно задается reArrangeNow = false.

Так что совет ZVV абсолютно точен.

[petergunn]

Цитата:

Сообщение от Ivanhoe

Может, в настройках модуля РП стоит Суммарная обработка = Нет, и этот параметр автоматически подтягивается в форму обработки накладной.

Цитата:

Сообщение от kalex_a

Вы правы, хотя я в передаю параметр

purchParmUpdate.SumBy = AccountOrder::None;

но такое чуство что он его не видит

'Программно' функционал класса purchFormLetter это действительно 'не видит' по причине того что часть логики отночительно значения reArrangeNow отрабатывает непосредственно на форме PurchEditLines и значение reArrangeNow передается в класс в качестве параметра (в методе new() класса PurchFormLetter reArrangeNow инициализируется значением true).

Цитата:

Сообщение от Sada

...
Нада посмотреть почему при стандартной оброботке эта переменная false

Можно отследить что происходит при работе с формой PurchEditLines при вызове purchFormLetter.prompt() в части работы с параметром reArrangeNow :

Forms\PurchEditLines\init():

...
sumBy.selection(purchEditLinesForm.sumBy());
element.sumByChanged(true);
...

метод purchEditLinesForm.sumBy():

AccountOrder  sumBy()
{;
    return PurchParameters::find().SummaryUpdateBy;
}

возвращает значение из параметров модуля "Рачеты с поставщиками". (В Вашем случае получается что "Суммарная обработка" = Нет)

Forms\PurchEditLines\sumByChanged():

void  sumByChanged(boolean _init)
{
...
if (_init && purchParmUpdate.SumBy == AccountOrder::None)
    reArrangeNow = false;
else
    reArrangeNow = true;

buttonReArrange.enabled(reArrangeNow);
...
}

На входе метода параметр _init = true, после открытия формы переменная reArrangeNow = false (визуально кнопка "Упорядочить" при этом недоступна). Если параметр "Суммарная обработка" не трогать, то при закрытии формы:

void  closeOk()
{
...
purchFormLetter.reArrangeNow(reArrangeNow);
...
}

значение false уходит в класс purchFormLetter, что Вы и констатировали:

Цитата:

Сообщение от kalex_a

, а если разносить через форму заказа ("Разноска" -> "Накладная" и т.д.) то она имеет значение "False".

При таком раскладе конструкция:

purchFormLetter.reArrangeNow(false);
...
purchParmUpdate.SumBy = AccountOrder::None;

вполне укладывается в штатное поведение Ax, imho

P.S. Oops... пока излагал свою мысль Ivanhoe уже ответил в тему.