коррекция налогов

[offenmeier]

бывает у меня нередко, что интегрирую AX со всякими системами, которые поставляют в AX данные в виде: я продал этому клиенту столько-то того-то, и он заплатил мне столько-то и налогов из этого столько-то.

и, соответственно, необходимо провести по аксапте в точности так, как дано. клиент-то уже заплатил.

довольно часто происходит, что внешняя система округляет налоги для каждой линии заказа, и в результате, когда аксапта делает invoice update появляется разница между тем, что пришло из внешней системы, и тем, что считает аксапта.

в этом случае я пользуюсь классом TaxRegulation.

void setTaxAmount(SalesId _sales, Amount _tax)
{
    SalesTotals     stotals = SalesTotals::construct(SalesTable::find(_sales));
    Tax             tax = stotals.tax();
    TaxRegulation   tregulation = TaxRegulation::newTaxRegulation(tax);
    ;

    tregulation.allocateAmount(_tax);
    tregulation.saveTaxRegulation();
}

где _tax - это то, что пришло из другой системы. Насколько такой метод уместен? В общем, это равноценно функции Tax при постинге инвойса. чем это чревато?

[raz]

Цитата:

Сообщение от offenmeier

в этом случае я пользуюсь классом TaxRegulation.

ИМХО, правильный выбор. Мы так же пользуемся при закачке из 1С. Только у нас посложнее будет, т.к. возможен разный налог (10% и 18%) в одном заказе.

[Tays]

Добрый день.

2 raz. Возникла проблема, когда данные по закупке приходят от поставщика в формате екселя. Система поставщика - 1С. Суммы налогов иногда имеют расхождения, как и описано в первом сообщении.

Цитата:

offenmeier

довольно часто происходит, что внешняя система округляет налоги для каждой линии заказа, и в результате, когда аксапта делает invoice update появляется разница между тем, что пришло из внешней системы, и тем, что считает аксапта.

Расскажите, как вы решили эту проблему вышеуказанным кодом с условием разных ставок налогов ?

Спасибо!

[raz]

2 Tays
примерно так:

        PurchFormLetter                = PurchFormLetter::construct(DocumentStatus);

        purchParmUpdate.clear();
        purchParmUpdate.SpecQty        = _purchUpdate;
        purchParmUpdate.DocumentStatus = DocumentStatus;
        purchParmUpdate.SumBy          = AccountOrder::Account;
        purchParmUpdate.ParmId         = PurchFormLetter.parmId();

        PurchFormLetter.purchTable(localPurchTable);
        PurchFormLetter.purchParmUpdate(purchParmUpdate);
        PurchFormLetter.initLinesQuery();

        PurchTotals = PurchTotals::construct(localPurchTable, _purchUpdate, AccountOrder::Account, PurchFormLetter.parmId(), '', DocumentStatus);
        PurchTotals.calc();

        tmpTaxWorkTrans.setTmpData(PurchTotals.tax().tmpTaxWorkTrans());
        taxRegulation = taxRegulation::NewTaxRegulation(tmpTaxWorkTrans);
        tmpTaxRegulationWork.setTmpData(taxRegulation.tmpTaxRegulation());

        while select sum(SourceTaxAmountCur) from tmpTaxRegulationBase group by TaxCode
        {
            select forupdate firstonly tmpTaxRegulationWork where
                tmpTaxRegulationWork.TaxCode == tmpTaxRegulationBase.TaxCode;

            if (tmpTaxRegulationWork.RecId &&
                tmpTaxRegulationWork.SourceRegulateAmountCur != tmpTaxRegulationBase.SourceTaxAmountCur)
            {
                tmpTaxRegulationWork.SourceRegulateAmountCur = tmpTaxRegulationBase.SourceTaxAmountCur;
                tmpTaxRegulationWork.update();
                taxRegulation.calcAndSaveTaxInCostPrice(tmpTaxRegulationWork);
            }
        }

        taxRegulation.saveTaxRegulation();

ЗЫ. В tmpTaxRegulationBase и tmpTaxRegulationWork записаны построчно данные от поставщика: налоговый код и сумма.

[Tays]

Спасибо.

[kalex_a]

А у меня не регулируется выдает ошибку ((

[raz]

Цитата:

Сообщение от kalex_a

А у меня не регулируется выдает ошибку ((

Если регламентирован налог, то:
1. нельзя обрабатывать группу документов;
2. параметр в обработке "Суммарная обработка" должен иметь значение "Нет"

[kalex_a]

Цитата:

Сообщение от raz

Если регламентирован налог, то:
1. нельзя обрабатывать группу документов;
2. параметр в обработке "Суммарная обработка" должен иметь значение "Нет"

"Суммарная обработка" имеет значение "Нет"

[kalex_a]

все равно не работает ((

[kalex_a]

хотя если вызвать purchFormLetter.prompt(), то все срабатывает