финансовые аналитики в диалог

[longson]

Добрый день,

Подскажите, если я использую RunBaseBatch как базовой класс для создания диалога, как можно добавить в диалог поле Финансовые аналитики раздельно ? Т.е 3 поля в диалог типа Dimension/

Спасибо.

[RVS]

Dimensions

[glibs]

Интересно стало.

Вот один из способов достижения результата. Код, правда, не дописан. Но как академический пример сойдет.

#Define.underline("_")
#Define.fieldNameTemplate("\%1_\%2")
static server void glibs(Args _args)
{
    Dialog              dialog = new Dialog();
    DialogField         dialogField;
    FormStringControl   formStringControl;
    FieldName           fieldName;
    Counter             pos,
                        i;
    ;

    dialogField = dialog.addField(typeid(Dimension));
    fieldName = dialogField.name();
    pos = strfind(fieldName, #underline, 1, 9999);
    if (pos)
    {
        fieldName = substr(fieldName, 1, pos - 1);
    }
    for (i = 1; i <= 3; i++)
    {
        if (i != SysDimension::Department + 1)
        {
            formStringControl = dialogField.control(strfmt(#fieldNameTemplate, fieldName, i));
            formStringControl.visible(false);
        }
    }
    formStringControl = dialogField.control(dialogField.name());
    dialog.run();

}

Есть вариант написать альтернативный .addField() в классе Dialog.

Но это теория. Просто хотелось разобраться и узнать что-то новое. На практике лучше так не делать. Проще создать расширенный тип. Я так делаю всегда.

[DSPIC]

Цитата:

Т.е 3 поля в диалог типа Dimension

Цитата:

Проще создать расширенный тип. Я так делаю всегда.

Быть может лучше использовать форму для диалога, в качестве датасорса которой указать таблицу TmpDimension. Это предотвратит модификацию подобных диалогов при появлении новых аналитик в системе.

[glibs]

Так все три (точнее все имеющиеся сразу) аналитики можно и так добавить. В 4.0, по крайней мере.

Я думал вопрос в том, как добавить одну.

[petergunn]

Цитата:

Сообщение от glibs

Интересно стало.

Вот один из способов достижения результата. Код, правда, не дописан. Но как академический пример сойдет.

#Define.underline("_")
#Define.fieldNameTemplate("\%1_\%2")
static server void glibs(Args _args)
{
    Dialog              dialog = new Dialog();
    DialogField         dialogField;
    FormStringControl   formStringControl;
    FieldName           fieldName;
    Counter             pos,
                        i;
    ;

    dialogField = dialog.addField(typeid(Dimension));
    fieldName = dialogField.name();
    pos = strfind(fieldName, #underline, 1, 9999);
    if (pos)
    {
        fieldName = substr(fieldName, 1, pos - 1);
    }
    for (i = 1; i <= 3; i++)
    {
        if (i != SysDimension::Department + 1)
        {
            formStringControl = dialogField.control(strfmt(#fieldNameTemplate, fieldName, i));
            formStringControl.visible(false);
        }
    }
    formStringControl = dialogField.control(dialogField.name());
    dialog.run();

}

Есть вариант написать альтернативный .addField() в классе Dialog.

Но это теория. Просто хотелось разобраться и узнать что-то новое. На практике лучше так не делать. Проще создать расширенный тип. Я так делаю всегда.

Для академичности примера лучше воспользоваться методом dialogField.fieldControl() для перебора диалоговых полей EDT Dimension, вариация приведенного job на эту тему:

static void jobDimensionFields(Args _args)
{
    Dialog              dialog              ;
    DialogField         dialogFieldDimension;
    FormStringControl   formStringControl   ;
    Counter             idx                 ;
    ;
    
    dialog = new Dialog() ;
    dialogFieldDimension = dialog.addField(typeId(Dimension));
 
    for( idx=2; idx<=Dimensions::numOfDimensions(); idx++ )
    {
        formStringControl = dialogFieldDimension.fieldControl(idx) ;
        formStringControl.visible( false ) ;
    }
 
    dialog.run() ;
}

[longson]

Спасибо за ответы. Собственно я сделал следующим образом

В методе dialog бдут

dlgDimension = dialog.addFieldValue(typeId(Dimension), dimension);

где dimension - переменная типа Dimension объявлена глобально в классе.

ну и естественно в методе getFromDialog будет

dimension = dlgDimension.value();

Тогда в диалог будут добавлены 3 поля - для каждой финансовой аналитики одно поле.

После этого в классе, где нужно использовать значения выбранной аналитики, просто пишу

str dimension1, dimension2, dimension3;

dimension1 = dimension[1];
dimension2 = dimension[2];
dimension3 = dimension[3];

Мне больше нравится этот вариант, т.к не требуется создавать новые EDT. Хотя, это для моей задачи. Возможно в других ситуациях реально новые EDT просто необходимы.