Не удаляется Range

[Elenka]

Добрый день!

У нас стоит Axapta версии 3.0 SP5. Пытаюсь в существующем запросе через объект query удалить Range по полю таблицы методом ClearRange и выставить Range со значением на это же поле снова. Пользовалась поиском по форуму, ничего подобного не нашла. Использовала уже, наверно, все способы использования Range, которые рекомендуются на форуме. На данный момент код выглядит так:

    queryRun = new QueryRun(_query); // _query передается в метод с клиента на сервер
    while (MapVTI.more())
    {
        AccountVT = MapVTI.key();
        qbds = queryRun.query().dataSourceTable(tablenum(VendTrans)); // запрос возвращается верный 
        qbr = queryRun.query().dataSourceTable(tablenum(VendTrans)).findRange(fieldnum(VendTrans,AccountNum)); // qbr ничего не возвращает (Value равно пустому месту, а не фильтру), хотя ранее фильтр был наложен
        qbds.clearRange(fieldnum(VendTrans,AccountNum));
        qbr = qbds.addRange(fieldnum(VendTrans,AccountNum));
        qbr.value(AccountVT);
    }

В результате вижу в запросе фильтр where (Поле1 = значение1 Or Поле1 = значение1), в том числе и в коде запроса, который был передан на испольнение в БД. Не могу понять, в чем может быть проблема.

[mazzy]

Цитата:

Сообщение от Elenka

Пытаюсь в существующем запросе через объект query удалить Range по полю таблицы методом ClearRange и выставить Range со значением на это же поле снова.

ClearRange не удаляет, а всего лишь очищает значение.

Не мучайтесь, а пользуйтесь стандартным SysQuery::findOrCreateRange(...)

[Elenka]

Я правильно понимаю, что qbr в данном случае:
qbr = SysQuery::findOrCreateRange(queryRun.query().dataSourceTable(tablenum(VendTrans)),fieldnum(VendTrans,AccountNum));
должно вернуть значение AccountNum=Значение1, если оно до этого было наложено?
Возвращаемых значений у меня почему то нет.

[mazzy]

Цитата:

Сообщение от Elenka

Я правильно понимаю, что qbr в данном случае:
qbr = SysQuery::findOrCreateRange(queryRun.query().dataSourceTable(tablenum(VendTrans)),fieldnum(VendTrans,AccountNum));
должно вернуть значение AccountNum=Значение1, если оно до этого было наложено?
Возвращаемых значений у меня почему то нет.

qbr имеет тип QueryBuildRange и содержит ссылку на найденный или только что созданный range.
далее вы должны установить значение в этот range

qbr = SysQuery::findOrCreateRange(queryRun.query().dataSourceTable(tablenum(VendTrans)),fieldnum(VendTrans,AccountNum));
qbr.Value(SysQuery::value("Значение1"))
;

[Elenka]

Все верно, данная функция возвравращает ссылку на ранее созданый range, но в Value пусто, хотя там должно быть accountNum=Значение1, поскольку первоначально фильтр по этому полю был наложен. Далее как Вы и говорите пишу qbr.Value(SysQuery::value("Значение1")) либо просто qbr.Value("Значение1"). В результате получаю в where запроса (accountNum = значение1 Or accountNum= значение1), поскольку изначально по неизвестной причине значение фильтра по этому полю система не увидела, и метод ClearRange не отработал. В результате имею запрос с избыточным фильтром, который мне сосвершенно не нужен.

[miklenew]

Поробуйте запрос посмотреть
info(query.dataSourceNo(1).toString());
Мож интересующее вас значение присваивается дальше(в другом классе или методе).

[Elenka]

Нет. Думаю, что это всё таки какой то глюк, связанный с тем, что исходный Query передается с клиента на сервер и что теряется.

[NeveB]

Возможно, в Query изначально 2 или более фильтров по полю AccountNum. попробуйте след. образом:

qbds = queryRun.query().dataSourceTable(tablenum(VendTrans)); 
while (qbds.findRange(fieldnum(VendTrans,AccountNum)))
{
   qbds.clearRange(fieldnum(VendTrans,AccountNum));
}
//тут наложить новый фильтр

П.С. clearRange именно удаляет фильтр, а не очищает имеющийся

[Hyper]

Как выглядит инициализация переменной _query? Учитывается ли QueryRun?
Что выдает _query.xml()?

[Elenka]

Нет, не учитывается. Изначально создается Query, в источник которого просто входит таблица VendTrans, потом этот Query передается в метод, где на него накладываются фильтры пользователя, потом результирующий Query передается на AOS, где я пыталась фильтр на одно из полей таблицы отключить и наложить другой (запускать не по всем поставщикам запрос, а по каждому в отдельности). В результате решила вопрос по другому. Изначально создаю 2 запроса, один с фильтром и группировкой по поставщикам, второй без фильтра. Далее в обработке, просто создаю каждый раз новый query, на основе первоначального без фильтра по поставщикам:

Query = new Query(_query);
Qbds = Query.dataSourceTable(tablenum(VendTrans));
qbr = Qbds.addRange(fieldNum(VendTrans,AccountNum));
qbr.value(AccountVT);

[Hyper]

Цитата:

Сообщение от Elenka

данная функция возвравращает ссылку на ранее созданый range, но в Value пусто, хотя там должно быть accountNum=Значение1, поскольку первоначально фильтр по этому полю был наложен. Далее как Вы и говорите пишу qbr.Value(SysQuery::value("Значение1")) либо просто qbr.Value("Значение1"). В результате получаю в where запроса (accountNum = значение1 Or accountNum= значение1)

Проблема в том, что первоначально у вас было два ranges: один пустой, а второй - "Значение1" (вы проверяли _query.xml()?). Когда вы делали clearRange, удалялся пустой range, а "Значение1" оставалось. После этого вы добавляли еще один range "Значение1", вот и получали в where запроса "(accountNum = значение1 Or accountNum= значение1)";
Следующий код это иллюстрирует:

static void JobTest(Args _args)
{
    Query                   q       = new Query();
    QueryBuildDataSource    qbds    = q.addDataSource(tablenum(VendTrans));
    ;

    qbds.addRange(fieldNum(VendTrans,AccountNum));
    qbds.addRange(fieldNum(VendTrans,AccountNum)).value('Test1');
    info(q.xml());
    qbds.clearRange(fieldnum(VendTrans,AccountNum));
    qbds.addRange(fieldNum(VendTrans,AccountNum)).value('Test2');
    info(qbds.toString());
}

Конечный запрос выглядит так:
"SELECT * FROM VendTrans WHERE ((AccountNum = N'Test1') OR (AccountNum = N'Test2'))"

[Russland]

Elenka
пропустите ваш запрос через

new DEV_QueryBrowser().run( query );

вы сможете увидеть и xml и sql выражения запроса

[mazzy]

Цитата:

Сообщение от Russland

Elenka
пропустите ваш запрос через

new DEV_QueryBrowser().run( query );

вы сможете увидеть и xml и sql выражения запроса

Э-э-э... А можно задать вопрос в целях повышения самообразованности?
А DEV_QueryBrowser() - это где?

[oip]

Тут.