Сравнение полей в запросе

[DreamCreator]

Добрый вечер!

Хотел бы сравнивть в запросе два поля по абсолютной величине (inventJournalTrans.Qty[оно в рамках задачи всегда меньше нуля] и inventJournalTrans.QtyRegistered)

Написал:

PHP код:

   while select inventJournalTrans
        where   inventJournalTrans.JournalId == _inventJournalTable.JournalId &&
                - inventJournalTrans.Qty       <   inventJournalTrans.QtyRegistered 


Ругается: Описание ошибки SQL: [Microsoft][ODBC SQL Server Driver]Недопустимое символьное значение для указания отклонения


Написал:

PHP код:

    qbds = query.addDataSource(tableNum(InventJournalTrans));
    qbrJournalId = qbds.addRange(fieldNum(InventJournalTrans,JournalId));
    qbrJournalId.value(_inventJournalTable.JournalId);

    qbrQty = qbds.addRange(fieldNum(InventJournalTrans,JournalId));
    qbrQty.value("(  inventJournalTrans.Qty > - inventJournalTrans.QtyRegistered)");

    queryRun = new queryRun(query);

    while (queryRun.next())
    {
        inventJournalTrans = queryRun.get(tableNum(InventJournalTrans));
        info(inventJournalTrans.ItemId);
    } 


Ругается Ошибка расширенного диапазона запроса: inventJournalTrans.Qty не является корректной парой datasource.field рядом с 29.

Ну, второе еще понятно - заведомо. Но решения не нашел..

[mit]

а так?

PHP код:

 while select inventJournalTrans 
        where   inventJournalTrans.JournalId == _inventJournalTable.JournalId  
         {
                if(abs(inventJournalTrans.Qty)       <   abs(inventJournalTrans.QtyRegistered ))
                {...}
         } 


[Ivan Mischenko]

Попробуйте скобочек добавить... так вроде.

[AndyD]

Во-первых,

qbds = query.addDataSource(tableNum(InventJournalTrans),"InventJournalTrans");

Во-вторых, JournalId надо тоже добавлять в расширенный диапазон, иначе соединение получается ч/з OR, а не AND

В-третьих, слегка извращенно это получится так

qbrQty.value("((inventJournalTrans.JournalId == \"" + _inventJournalTable.JournalId + "\") &&  
(inventJournalTrans.Qty - inventJournalTrans.Qty < inventJournalTrans.Qty + inventJournalTrans.QtyRegistered))");

PS. Select можно построить по этому-же принципу

 while select inventJournalTrans
        where   inventJournalTrans.JournalId == _inventJournalTable.JournalId &&
                inventJournalTrans.Qty - inventJournalTrans.Qty       <   
                inventJournalTrans.Qty + inventJournalTrans.QtyRegistered

[Dron AKA andy]

Это что-то у вас с полем QtyRegistered не то. Если написать глупый запрос

while select inventJournalTrans 
        where   inventJournalTrans.JournalId == _inventJournalTable.JournalId && 
                - inventJournalTrans.Qty       <   inventJournalTrans.SalesAmount

- не ругается.

Во втором случае в скобках не нужно указывать "inventJournalTrans":

PHP код:

    qbrQty.value("(Qty > -QtyRegistered)"); 


[DreamCreator]

Спасибо за советы -- сейчас пробую!

Цитата:

Сообщение от mit

а так?

Так вчера и сделал, но хочется оптимальнее выборку!

2 Ivan Mischenko, AndyD

Сейчас пробую. Спасибо!

2 Dron AKA andy

У меня и на этот запрос ругается аналогично!

[DreamCreator]

Цитата:

Сообщение от AndyD

Во-вторых, JournalId надо тоже добавлять в расширенный диапазон, иначе соединение получается ч/з OR, а не AND
..
PS. Select можно построить по этому-же принципу

 while select inventJournalTrans
        where   inventJournalTrans.JournalId == _inventJournalTable.JournalId &&
                inventJournalTrans.Qty - inventJournalTrans.Qty       <   
                inventJournalTrans.Qty + inventJournalTrans.QtyRegistered

С циклом получилось! Написал так:

PHP код:

 while select inventJournalTrans
        where   inventJournalTrans.JournalId == _inventJournalTable.JournalId &&
                0 - inventJournalTrans.Qty > 0 + inventJournalTrans.QtyRegistered 


Через query не получилось -- Ошибка расширенного диапазона запроса: Синтаксическая ошибка рядом с 52.

PHP код:

static void testMatchingFieldsByQuery(Args _args)
{
    Query                   query = new Query();
    QueryBuildDataSource    qbds;
    QueryBuildRange         qbrQty;
    QueryRun                queryRun;
    InventJournalTrans      inventJournalTrans;
    InventJournalTable      inventJournalTable = InventJournalTable::find('075221_090');
    ;

    qbds = query.addDataSource(tableNum(InventJournalTrans),"InventJournalTrans");
    qbds.addRange(fieldNum(InventJournalTrans,JournalId)).value(inventJournalTable.JournalId);
    qbds.addRange(fieldNum(InventJournalTrans,IncompleteDelivery)).value(queryValue(NoYes::No));
    qbrQty = qbds.addRange(fieldNum(InventJournalTrans,JournalId));
    qbrQty.value("((inventJournalTrans.JournalId == \"" + inventJournalTable.JournalId + @"\) &&
        (inventJournalTrans.Qty - inventJournalTrans.Qty < inventJournalTrans.Qty + inventJournalTrans.QtyRegistered))");

    queryRun = new queryRun(query);

    while (queryRun.next())
    {
        inventJournalTrans = queryRun.get(tableNum(InventJournalTrans));
        info(inventJournalTrans.ItemId);
    }
} 


Немного переписал -- но без этого не компилировалось, думаю идею сохранил.

[Wamr]

Уже когда-то писал

PHP код:

 while select inventJournalTrans 
        where   inventJournalTrans.JournalId == _inventJournalTable.JournalId && 
                -1 * inventJournalTrans.Qty       <   inventJournalTrans.QtyRegistered 


Кстати, на Оракле и без этого работает

[DreamCreator]

Работает!

[Wamr]

Аналогично

PHP код:

static void testMatchingFieldsByQuery(Args _args) 
{ 
    Query                   query = new Query(); 
    QueryBuildDataSource    qbds; 
    QueryBuildRange         qbrQty; 
    QueryRun                queryRun; 
    InventJournalTrans      inventJournalTrans; 
    InventJournalTable      inventJournalTable = InventJournalTable::find('075221_090'); 
    ; 

    qbds = query.addDataSource(tableNum(InventJournalTrans),"InventJournalTrans"); 
    qbds.addRange(fieldNum(InventJournalTrans,JournalId)).value(inventJournalTable.JournalId); 
    qbds.addRange(fieldNum(InventJournalTrans,IncompleteDelivery)).value(queryValue(NoYes::No)); 
    qbrQty = qbds.addRange(fieldNum(InventJournalTrans, Qty)); 
    qbrQty.value("(-1*inventJournalTrans.Qty < inventJournalTrans.QtyRegistered)"); 

    queryRun = new queryRun(query); 

    while (queryRun.next()) 
    { 
        inventJournalTrans = queryRun.get(tableNum(InventJournalTrans)); 
        info(inventJournalTrans.ItemId); 
    } 
} 


[AndyD]

Это не надо. Уже включено в расширенный диапазон
qbds.addRange(fieldNum(InventJournalTrans,JournalId)).value(inventJournalTable.JournalId);

Прошу прощения, перенос я вставил только для того, чтобы строка нормально читалась в браузере. На самом деле надо так

qbrQty.value("((inventJournalTrans.JournalId == " +
    "\"" + _inventJournalTable.JournalId + "\") && " + 
    "(inventJournalTrans.Qty - inventJournalTrans.Qty < " +
    "inventJournalTrans.Qty + inventJournalTrans.QtyRegistered))");

либо убрать перенос.

Если IncompleteDelivery тоже должно быть ч/з AND, то его необходимо внести в расширенный Range

[Wamr]

AndyD Не надо ничего добавлять в расширенный range. Надо просто его сделать по правильному полю и тогда все условия будут через AND

[DreamCreator]

Оба варианта с query корректно сработали!

Wamr и AndyD спасибо и респект!