Не понятно что случилось с inventtrans

[S.Kuskov]

Для поиска удалённых данных, могу подкинуть один джобик.

// Восстанавливает в таблицу <toTable> записи удеалённые из таблицы <fromTable>
// !!! имена полей (и желательно их типы :) должны совпадать

static void RestoreToTable(TableId fromTableId, TableId toTableId, date fromDate, date toDate, UserId deletedBy = "")//, createdTransactionId _createdTransactionId)
{
    SysDataBaseLog  SysDataBaseLog;
    list            datalist;
    listEnumerator  enumerator;
    container       tmp;
    int             i;
    dictTable       toDictTable = new dictTable(toTableId);
    dictTable       fromDictTable = new dictTable(FromTableId);
    DictField       toDictField;
    DictField       fromDictField;
    FieldId         toFieldId;
    FieldId         fromFieldId;
    int             toCntFields;
    int             arrayCount;
    int             arrayIdx;
    FieldName       fromFieldName;
    FieldName       toFieldName;
    Common          Common;

    SysOperationProgress DialogProgress;
    int DialogProgress_cntAll;
    int DialogProgress_cnt = 0;
    ;

    DialogProgress = new SysOperationProgress();
    DialogProgress.setCaption("Восстановление удалённых записей");
    DialogProgress.setTotal(100);

    select count(RecId) from SysDataBaseLog
    where
        SysDataBaseLog.table == fromTableId
        && SysDataBaseLog.createdDateTime >= datetimeutil::newDateTime(fromDate, 0)
        && SysDataBaseLog.createdDateTime < datetimeutil::newDateTime(toDate + 1, 0)
        && (deletedBy == "" || SysDataBaseLog.createdBy == deletedBy)
        && SysDataBaseLog.LogType == DatabaseLogType::Delete
;//        && SysDataBaseLog.createdTransactionId == _createdTransactionId;

    DialogProgress_cntAll = SysDataBaseLog.RecId;

    while select SysDataBaseLog
    where
        SysDataBaseLog.table == fromTableId
        && SysDataBaseLog.createdDateTime >= datetimeutil::newDateTime(fromDate, 0)
        && SysDataBaseLog.createdDateTime < datetimeutil::newDateTime(toDate + 1, 0)
        && (deletedBy == "" || SysDataBaseLog.createdBy == deletedBy)
        && SysDataBaseLog.LogType == DatabaseLogType::Delete
//        && SysDataBaseLog.createdTransactionId == _createdTransactionId
    {
        DialogProgress.setText(strfmt
        (
            "Восстановленно записей: %1 из %2",
                    DialogProgress_cnt,
                    DialogProgress_cntAll
        ));

        Common = toDictTable.makeRecord();
        datalist = SysDataBaseLog.getDataAslist();
        enumerator = dataList.getEnumerator();
        while (enumerator.moveNext())
        {
            tmp = enumerator.current();
            fromFieldId = conpeek(tmp, 1);

            fromDictField = new dictField(fromDictTable.id(), fromFieldId);
            fromFieldName = fromDictField.name();

            toCntFields = toDictTable.fieldCnt();
            for (I = 1; I <= toCntFields; I++)
            {
                toDictField = new dictField(toDictTable.id(), toDictTable.fieldCnt2Id(I));
                toFieldId = toDictField.id();
                arrayCount = toDictField.arraySize();
                for (arrayIdx = 1; arrayIdx <= arrayCount; arrayIdx ++)
                {
                    toFieldId += 65536;
                    toDictField = new dictField(toDictTable.id(), toFieldId);
                    toFieldName = toDictField.name();
                    if (toFieldName == fromFieldName)
                    {
                        Common.(toDictField.id()) = conpeek(tmp, 2);
                    }
                }
            }
        }
        toFieldId = toDictTable.fieldName2Id("DeletedBy");
        if (toFieldId > 0) Common.(toFieldId) = SysDataBaseLog.createdBy;

        toFieldId = toDictTable.fieldName2Id("DeletedDateTime");
        if (toFieldId > 0) Common.(toFieldId) = SysDataBaseLog.createdDateTime;

        toFieldId = toDictTable.fieldName2Id("DeletedTransactionId");
        if (toFieldId > 0) Common.(toFieldId) = SysDataBaseLog.createdTransactionId;


        Common.insert();

        DialogProgress_cnt++;
        DialogProgress.setcount(DialogProgress_cnt*100/DialogProgress_cntAll);
    }
}

Рекомендую сделать дубликат InventTrans (правой кнопке по таблицув, пункт Дублировать) и восстановить данные туда. Также если в CopyOfInventTrans добавить поля DeletedBy, DeletedDateTime и DeletedTransactionId, то они также заполнятся

[Che]

Цитата:

Сообщение от pitersky

А вообще изменения InventTrans у вас в лог пишутся? Если да, то попробуйте найти максимально похожий код журнала и накладывать фильтр по нему.
Например - вы ищете журнал "Прих00111". Если у вас явно есть журнал "Прих00110", то попробуйте наложить фильтр "Прих0011?". Если ничего не отфильтруется, то это будет именно проблемой фильтрации лога

Блин ничего понять не могу - что в тестовой что в реальной - по этому журналу ничего нет... тип изменения - delete стоит (насколько я помню это настраивается). но все же, получается что этот журнал из инвенттранса не удалял никто (т.к. в логе увидел другие удаленные журналы)

[lev]

Цитата:

Сообщение от S.Kuskov

Для поиска удалённых данных, могу подкинуть один джобик.
...
Рекомендую сделать дубликат InventTrans (правой кнопке по таблицув, пункт Дублировать) и восстановить данные туда. Также если в CopyOfInventTrans добавить поля DeletedBy, DeletedDateTime и DeletedTransactionId, то они также заполнятся

можно проще на форме "Журнал базы данных" есть кнопка "Вставка заново".
Встаете на нужную запись и нажимаете кнопку.

[lev]

Цитата:

Сообщение от Che

Блин ничего понять не могу - что в тестовой что в реальной - по этому журналу ничего нет... тип изменения - delete стоит (насколько я помню это настраивается). но все же, получается что этот журнал из инвенттранса не удалял никто (т.к. в логе увидел другие удаленные журналы)

точно никто не делал doDelete() (может в какой функции вызывается) со скипами?
или напрямую в БД никто ничего не делал?

[Wamr]

Люди, ау. Какое логирование inventTrans? У вас много лишнего дискового пространства?
В некоторых случаях (если полная аналитика указывалась в строках журнала) можно восстановить проводки по связанным таблицам (InventJournalTrans, InventTransPosting, InventSettlement)... джобиком

[Che]

Цитата:

Сообщение от lev

точно никто не делал doDelete() (может в какой функции вызывается) со скипами?
или напрямую в БД никто ничего не делал?

напрямую - точно
пересчеты никакие никто не запускал... Каждый день формируется физическое наличие (значения с инвенттранса). Вчера не понятно с чего остатки слетели

[S.Kuskov]

Цитата:

Сообщение от lev

можно проще

Согласен. Этот джоб я использовал не столько ради самого восстановления данных сколько ради поиска кем и когда они были удалены (не всегда описния записи хватает для её идентификации).

[Wamr]

так как пропали "приходные проводки в закрытых периодах" и "вдруг поплыли остатки", то можно предложить такой вариант восстановления:
1. поднять рядом бекап от позовчера
2. джобиком скопировать недостающие проводки из восстановленной базы в рабочую

джобиком, чтобы сделать аксаптовский insert с автоматическим пересчетом InventSum

------------
подумал...
остатки 0, есть InventTransPosting, значит скорее всего InventSum и до удаления был 0, значит надо переносить проводки через doInsert (или прям на SQL), как раз чтобы InventSum не пересчитался.

[lev]

Вспомнил. Есть такая функция как "Проверка целостности данных компании".
Для начала вопрос знатокам
Эта функция восстановит отсутствующие проводки?

[Wamr]

нет.. она правит InventSum под существующие проводки.

[Che]

Цитата:

Сообщение от Wamr

так как пропали "приходные проводки в закрытых периодах" и "вдруг поплыли остатки", то можно предложить такой вариант восстановления:
1. поднять рядом бекап от позовчера

подумал...
остатки 0, есть InventTransPosting, значит скорее всего InventSum и до удаления был 0, значит надо переносить проводки через doInsert (или прям на SQL), как раз чтобы InventSum не пересчитался.

инвентсум пересчитать смогу, отресторить тестовую за позавчера смогу.... но вот как с отресторенной тестовой строки с инвенттранса перекинуть - ума не приложу
Уже начал всерьез задумываться о ресторе реальной... пусчай 2 дня восстанавливают

[S.Kuskov]

Цитата:

Сообщение от lev

Эта функция восстановит отсутствующие проводки?

Ага и ещё все орфаграфические ошибки исправит.

[lev]

Цитата:

Сообщение от S.Kuskov

Ага и ещё все орфаграфические ошибки исправит.

не понял стеба...

я имел ввиду она только inventSum пересчитает, или проводки тоже как то затрагивает...

wamr меня правильно понял, и ответил на интересующий вопрос, спасибо

[Wamr]

Che (простите, Ваш ник пару раз в русской раскладке написал)
сначала определитесь нужно ли пересчитывать InventSum... как говорил lev, выполните "проверку целостности" по складу и выбранной номенклатуре в режиме проверки.
Если процедура будет ругаться, то значит надо нести проводки через классический SQL.
если не будет, то джобиком.

думаю, вам помогут... только скажите, что именно нужно

[Wamr]

и еще...
посмотрите все джобики на рабочей, где упоминается inventTrans или delete
и вспомните какие модификации делались за последнюю неделю

[Che]

насторожило: "какие модификации делались за последнюю неделю"
...если, допустим, неделю назад что то запускали, то как тогда объяснить что до вчера остатки нормальные были... получается же что то вчера "случилось"
Как я понял, проверка целостности не восстановит недостающие проводки по инвенттрансу - стоит ли тогда ее запускать?

[Che]

подскажите еще - как правильно в моем случае отловить строки по отсутствующим журналам в инвенттрансе. Пишу:

PHP код:

static void Job71(Args _args)
{
inventjournaltable      jTb;
Inventtrans             iTrans;

while select jTb where jTb.PostedDate && jTb.PostedDate >= mkDate(21,07,2010) && jTb.Posted
{
 select firstonly iTrans where iTrans.TransRefId == jTb.JournalId;
 if (!iTrans)
 {
 info(jTb.JournalId);
 }
}
} 


но отрабатывает очень долго... Видимо что то не учел

[lev]

Цитата:

Сообщение от Che

подскажите еще - как правильно в моем случае отловить строки по отсутствующим журналам в инвенттрансе. Пишу:

PHP код:

static void Job71(Args _args)
{
inventjournaltable      jTb;
Inventtrans             iTrans;

while select jTb where jTb.PostedDate && jTb.PostedDate >= mkDate(21,07,2010) && jTb.Posted
{
 select firstonly iTrans where iTrans.TransRefId == jTb.JournalId;
 if (!iTrans)
 {
 info(jTb.JournalId);
 }
}
} 


но отрабатывает очень долго... Видимо что то не учел

лучше по inventTransId.
т.е. перебираете строки журналов (можно с джойном на журналы) и далее поиск проводки:

Select firstonly inventTrans
where inventTrans.inventTransId == InventJournalTrans.InventTransId;

[lev]

Или вообще одним запросом типа:

while select InventJournalTrans
where inventJournalTrans.TransDate == 21\07\2010 
// и ещё что то там
notExists join inventTrans
where inventTrans.InventTransId == InventJournalTrans.inventTransId

[Che]

Еще один микровопрос, если кто есть трезвый ) Возможно ли в скуле напрямую скопировать табличку (например CustTable, VendTable) с одной бд - тестовой (Ctrl +C - т.е. без кода) и вставить на другую (Ctrl + V)...
Простите если вопрос дилетанта)))

Огромаднейшее спасибо за советы! Всех с наступающим!!!