Проверить в файле DBF наличие поля?

[Poleax]

Как проверить в файле DBF если ли поле вообще, при этом имя поля мы знаем?

[kornix]

Можно попробовать через класс CCADOField (код изначально не мой, переделал с помощью примера GBH ):

static server void dbfField()
{
    CCADOConnection         adoConnection;
    CCADOCommand           adoCommand;
    CCADORecordSet          adoRecordSet;
    CCADOFields                adoFields;
    ;

    adoConnection       = new CCADOConnection();

    // инициализация строки подключения ...

    adoConnection.open();
    adoCommand          = new CCADOCommand();
    adoCommand.activeConnection(adoConnection);

    adoCommand.commandType(1);   
    adoCommand.commandText("Select * from base.dbf");
    adoRecordSet     = adoCommand.execute();
    adoFields        = adoRecordSet.fields();
    if(adoFields.itemIdx(1))
    {
        // поле существует
    }
    else
    {
        // не существует
    }
            
    
    adoConnection.close();
    
}

[sukhanchik]

Также для получения информации о структуре таблиц существует объект ADOX. (классы CCADOX).

[Poleax]

Спасибо за ваши рекомендации. Вопрос решен через перебор имен полей.

void ado_FieldCheck() 
{
    #CCADO
    #define.GUID("GUID")
    //Classes
    CCAdoConnection         adoConnection = new CCAdoConnection();
    CCAdoCommand            adoCommand;
    CCAdoRecordSet          adoRecordSet;
    CCAdoFields             adoFields;
    
    //Variables
    int                     i;
    str 100                 connectionString  = strfmt('DSN=%1;',CustParameters::find().DsnImport); 
// DsnImport  преднастроенный DSN. На подобии как в форме импорта КЛАДР
    boolean                 ret = false;
    ;

    adoConnection.open(connectionString);
    adoCommand          = new CCADOCommand();
    adoCommand.activeConnection(adoConnection);

    adoCommand.commandType(#adCmdText);
    adoCommand.commandText("SELECT TOP 1 * FROM TEST.DBF");
    adoRecordSet     = adoCommand.execute();
    adoFields        = adoRecordSet.fields();

    for(i=0; i< adoFields.count(); i++)
    {
        if(adoFields.itemIdx(i).name() == #GUID)
        {
            ret = true;
            break;
        }
    }

    adoConnection.close();
    
    if(ret)
        info(strfmt('Поле %1 найдено.', #GUID));
    else
        info(strfmt('Поле %1 НЕ найдено.', #GUID));
}

Использовал информацию:
DSN для dbf файла
Connecting to Databases through X++

[sukhanchik]

Такой перебор плох тем, что для перебора нужно осуществить выборку из DBF. Т.е. если вдруг файл очень большой - то может уйти большое время для такого перебора.
Выкладываю (для потомков уже) пример работы с ADOX (слизано с класса CCADOCommandBuild). Код написан для 2009 RU5. В 4.0 можно было еще не пользоваться объектом COM - были нужные классы

static void Job1(Args _args)
{
    CCADOConnection   ccADOConnection;
    COM               ccADOXCatalog;   // Эх, а в 4.0 этот класс был...
    COM               ccADOXTables;    // А это семейство было в классе CCADOXCatalog от 4.0
    COM               ccADOXTable;     // Эх, а в 4.0 этот класс тоже был...
    COM               ccADOXColumns;   // А это семейство было в классе CCADOXTable от 4.0
    CCAdoxColumn      ccAdoxColumn;
    int               i;
    #define.myConnectionString('MyConnectionString')
    #define.myTableName('myTableName')
   ;
    ccADOConnection = new CCADOConnection();
    ccADOConnection.open(#myConnectionString);
    ccADOXCatalog = new COM('ADOX.Catalog');
    if (!ccADOXCatalog)
    {
        throw error("@SYS32731");
    }
    ccADOXCatalog.activeConnection(ccADOConnection.connection());
    ccADOXTables  = ccADOXCatalog.tables();
    ccADOXTable   = ccADOXCatalog.item(#myTableName);
    ccADOXColumns = ccADOXTable.columns();
    for (i = 0; i < ccADOXColumns.count(); i++)
    {
        ccAdoxColumn = new CCAdoxColumn(ccADOXColumns.item(i));
        info(strfmt("%1 %2", ccAdoxColumn.name(), ccAdoxColumn.xppType()));
    }
}

[player]

То есть "select TOP 1.." все равно на dbf вызовет загрузку всей таблицы?

[sukhanchik]

Цитата:

Сообщение от player

То есть "select TOP 1.." все равно на dbf вызовет загрузку всей таблицы?

Нет конечно.... В изначальной версии примера TOP 1 не было - поэтому на окончательную версию примера я и не взглянул. Извиняюсь.
Т.е. с TOP 1 все будет ок.