Лукап, отображающий список полей определённой таблицы

[Damn]

Изучая метод pickField() наткнулся на метод findFields() таблицы TmpSysTableField.
Есть там такой вот участок

                    field       = new SysDictField(dictTable.id(), dictTable.fieldCnt2Id(i), j);

                    if ((field.flags()      &  #DBF_VISIBLE) &&
                        (field.flags()      &  #DBF_STORE) &&
                        (field.baseType()   != Types::CONTAINER) &&
                        (field.name()       != fieldStr(Common, dataAreaId)) &&
                        (field.name()       != fieldStr(Common, sequenceNum)) &&
                        (field.name()       != fieldStr(Common, tableId)) &&
                        (field.baseType()   != Types::VARSTRING))
                    {
                        elements++;
                        pack = conIns(pack, elements, [dictTable.fieldCnt2Id(i),
                                                       field.extendedFieldId(),
                                                       field.name(),
                                                       field.label(),
                                                       field.help(j),
                                                       field.extendedTypeId(),
                                                       field.baseType()]);
                    }

Ну вот почему в случае поля с типом Dimension метод field.name() возвращает просто "Dimension", причём несколько (кол-во аналитик) раз ? Вроде как ожидается что-то типа "Dimension[1]", "Dimension[2]" и т.д. Конечно можно легко заменить field.name() методом fieldid2name() или ещё как-то, чтобы добиться требуемого результата, но почему изначально-то правильно не работает ...
Вобщем вот, высказался
P.S. Проверено в 3.0 SP5 и 4.0 SP1

[kashperuk]

на самом деле, думаю работает все правильно.
Поле в АОТ одно. Но оно является массивом. Поэтому перебираются все элементы массива. Но название поля то одно и то же.

Другое дело, что в базе данных это поле хранится как отдельные поля.
Но при просмотре поля в базе данных все отрабатывает как положено

static void tutorial_SysDictFieldDimension(Args _args)
{
    SysDictField fld = new SysDictField(tableNum(LedgerJournalTable), fieldNum(LedgerJournalTable, Dimension));
    ;
    info(fld.name());

    info(fld.name(DbBackend::Sql, 1));
    info(fld.name(DbBackend::Sql, 2));
    info(fld.name(DbBackend::Sql, 3));
}

Или я чего-то недопонял?

[Damn]

И в итоге метод pickField() отобразит на экране окошко типа
...
AccountNum
CurrencyCode
Dimension
Dimension
Dimension
...
не очень как-то удобно видеть дименшны без номеров

[kashperuk]

Да, согласен. Может возникнуть непонятка.

Поэтому стоит делать так: (в смысле, выводить кроме названия поля еще и его метку)
http://www.axaptapedia.com/Image:SelectFields.PNG

[propeller]

Есть ли в аксапте метод вроде pickField() только чтобы выпадал список не name а label полей таблицы ?
или как можно создать такой метод?

[tricky]

Я такого метода не знаю. Но если программировать, придется чуток покорежить парочку классов.
Можно сделать более "тактичнее", но если делать "в лоб", то примерно вот так.
1. В BaseEnum SysPickListType добавить еще один элемент. Пусть он будет называться FieldsLabels.
2. В классе Global добавить еще один метод, почти такой же, как и метод pickField

static int pickFieldLabel(tableId tableId)
{
    Object  formRun;
    Args    args;
    ;
    args = new Args(formstr(SysPick));
    args.parm(strRFix(int2str(SysPickListType::FieldsLabels),2)+int2str(tableId));
    formRun = classfactory.formRunClass(args);
    formRun.init();
    formRun.run();
    formRun.wait();
    if (formRun.selection())
        return formRun.selection();
    return 0;
}

3. В класс sysPickList, по аналогии с методом fillFieldsMap, добавить еще один метод:

public static client container fillFieldsLabelsMap(str _argsParm)
{
    TmpSysTableField    tmpSysTableField;
    DictTable           dictTable       = new DictTable(str2int(_argsParm));
    Map                 map             = new Map(Types::Integer, Types::String);
    ;
    if (dictTable &&
        dictTable.rights() > AccessType::NoAccess)
    {
        tmpSysTableField = TmpSysTableField::findTableFields(tmpSysTableField, dictTable.id());

        while select tmpSysTableField
        {
            map.insert(tmpSysTableField.ExtendedFieldId, tmpSysTableField.FieldLabel);
        }
    }
    return map.pack();
}

4. В методе init этого же класса добавить примерно такие строки (в блоке switch(sysPickListType)):

//-------------
        case SysPickListType::FieldsLabels :
            imageRes    = #imageField;
            caption     = "@SYS3852";
            designWidth = #designLargeWidth;
            if (!map)
            {
                map = Map::create(sysPickList::fillFieldsLabelsMap(parmTxt));
            }
            break;
//-------------

5. Теперь можно попробовать вызвать наш новый метод:

    Global::pickFieldLabel(tableNum(InventTable));

[Poleax]

По аналогии с выше приведенным постом tricky, я сделал для себя выпадающий список (Lookup) для всех полей таблицы не являющимися системными:
Результат:

1. В \Data Dictionary\Base Enums\SysPickListType добавить элемент, назовем его к примеру FieldsUsersLabels (Пользовательские поля с названием)
2. В классе создадим метод \Classes\Global\pickFieldUserLabel
   

   static int pickFieldUserLabel(tableId tableId)
   {
       Object  formRun;
       Args    args;
       ;
       args = new Args(formstr(SysPick));
       args.parm(strRFix(int2str(SysPickListType::FieldsUsersLabels),2)+int2str(tableId));
       formRun = classfactory.formRunClass(args);
       formRun.init();
       formRun.run();
       formRun.wait();
       if (formRun.selection())
           return formRun.selection();
       return 0;
   }

3. В класс создадим метод \Classes\sysPickList\fillFieldsUserLabesMap:
   

   public static client container fillFieldsUserLabesMap(str _argsParm)
   {
       TmpSysTableField    tmpSysTableField;
       DictTable           dictTable       = new DictTable(str2int(_argsParm));
       Map                 map             = new Map(Types::Integer, Types::String);
       
       //Variables
       DictField               dictField;
       SysDimension            dim;
       str                     num = '';
       
       ;
       if (dictTable &&
           dictTable.rights() > AccessType::NoAccess)
       {
           tmpSysTableField = TmpSysTableField::findTableFields(tmpSysTableField, dictTable.id());
   
           while select tmpSysTableField
           {
               dictField  = new dictField(dictTable.id(), tmpSysTableField.ExtendedFieldId);
               
               if(!dictField.isSystem())
               {
                   if(tmpSysTableField.FieldName LIKE "*Dimension*")
                       num = "[" + int2str(enum2int(str2Enum(dim, tmpSysTableField.FieldLabel)) + 1) + "]";
                   else
                       num = "";
                       
                   map.insert(tmpSysTableField.ExtendedFieldId, tmpSysTableField.FieldName + num + " (" + tmpSysTableField.FieldLabel + ")" );
               }
           }
       }
       return map.pack();
   }

4. В методе init этого же класса добавить примерно такие строки (в блоке switch(sysPickListType)):
   

           case SysPickListType::FieldsUsersLabels :
               imageRes    = #imageField;
               caption     = "Пользовательские поля с названием";
               designWidth = #designLargeWidth;
               if (!map)
               {
                   map = Map::create(sysPickList::fillFieldsUserLabesMap(parmTxt));
               }
               break;

5. Вызываем метод:
   

   Global::pickFieldUserLabel(tableNum(CustTable));

Для примера можно выбрать форму для изучения \Forms\PBATreeTable.

Пример Lookup метода:

void lookup()
{
    fieldId id;
//AnyUserTable  - таблица куда сохраняем поле
    ;

    id = pickFieldUserLabel(tableNum(CustTable));

    if (! id)
        return;

    AnyUserTable.FieldName = fieldid2name(tableNum(CustTable),id);

    AnyUserTable_ds.refresh();
}

P.S. Спасибо tricky , за хороший пост.

[lev]

ну и в дагонку методам pick (может кому пригодится )..
в своё время нужны были методы, которые вываливают список EDT, Forms и MainMenu.
т.к. в стандарте таковых не нашел добавил следующие методы в класс Global:

Ax3.0 sp3

1. список EDT:

static int pickExtDataTypes()
{
    Object      formRun;
    container   names;
    int         i;
    Dictionary  dict = new Dictionary();
    DictType    dictType;
    #ResAppl
    ;

    formRun = classFactory.createPicklist();
    formRun.init();

    for (i=1; i <= dict.typeCnt(); i++)
    {
        dictType = new DictType(dict.typeCnt2Id(i));

        names   += dictType.name();
    }

    formRun.choices(names, #ImageEDT);
    formRun.caption("EDT");
    formRun.run();
    formRun.wait();

    if (formRun.choice())
    {
        return dict.typeName2Id(formRun.choice());
    }

    return 0;
}

2. Список форм.

static FormName pickForms()
{
    Object      formRun;
    container   names;
    TreeNode    treeNode;
    TreeNode    treeNodeChild;
    #ResAppl
    #AOT
    ;

    treeNode        = TreeNode::findNode(#FormsPath);
    treeNodeChild   = treeNode.AOTfirstChild();

    formRun = classFactory.createPicklist();
    formRun.init();

    while (treeNodeChild)
    {
        names   += treeNodeChild.treeNodeName();

        treeNodeChild = treeNodeChild.AOTnextSibling();
    }

    formRun.choices(names, #ImageForm);
    formRun.caption("Forms");
    formRun.run();
    formRun.wait();

    if (formRun.choice())
    {
        return formRun.choice();
    }

    return '';
}

3. Список пунктов главного меню

static MenuName pickMenusMain()
{
    Object      formRun;
    container   names;
    TreeNode    treeNode;
    TreeNode    treeNodeChild;
    SysDictMenu dictMenu;
    #ResAppl
    #AOT
    #Admin
    ;

    treeNode        = TreeNode::findNode(#MenusPath + '\\' + #MainMenu);
    treeNodeChild   = treeNode.AOTfirstChild();

    formRun = classFactory.createPicklist();
    formRun.init();

    while (treeNodeChild)
    {
        dictMenu    = SysDictMenu::newMenuName(#MainMenu + '\\' + treeNodeChild.treeNodeName());
        names      += dictMenu.label();

        treeNodeChild = treeNodeChild.AOTnextSibling();
    }

    formRun.choices(names, #ImageMenuMain);
    formRun.caption("MainMenu");
    formRun.run();
    formRun.wait();

    if (formRun.choice())
    {
        return formRun.choice();
    }

    return '';
}